# Form Tutorial

Deutsch (de) English (en)

A short introduction on using Forms in Lazarus.

## What is a Form?

The form (class TForm) represents a window or dialog box that is the user interface of an application. It is the container on which all other components (e.g. buttons, labels, edit fields, images, etc.) are inserted .

## The First GUI Application

Upon successfully installing Lazarus and starting a new Application Project, an empty form is created. Otherwise you can create a new GUI application under Main menu -> Project -> New Project -> Application OK.

Now you have created a new, fully functional project with a form:

To run the newly created project, you can simply press the [F9] key or click with the mouse on the main menu icon (or Main menu: Run -> Run). The project will be compiled and executed.

Nothing really exciting happens. The form (Form1) changes slightly in appearance and the points from the raster grid (help for positioning of individual components) disappear (as long as the grid points are visible, you also know that it is still in design mode):
->

Next, you can place a TButton onto the form. This will be used later to allow the opening of a second form:

Select the TButton from the standard component palette

and click on the form: There is now a button placed on Form1 with the name and caption "Button1".

In order for this button to do something, you have to announce that you intend to do something when you click it. This can be regarded as a simple event. For this you need an event handler that is called after the click. The event handler for a mouse click can be quite easily reached by double-clicking on Button1 (or in the Object Inspector, select Button1 -> Events tab -> OnClick, then click on the [...] button). This creates a procedure TForm1.Button1Click in the code editor, which is always called (at run time, not in design time) when Button1 is clicked:

To make the application do something after clicking on Button1, add some code between the begin and end of the procedure TForm1.Button1Click like this:

procedure TForm1.Button1Click(Sender: TObject);
begin
Caption:='My first Form';  //Caption of Form1 is changed (text in formhead)
//or
Button1.Caption:='Hello';  //Caption of button is changed (shown text of button)
end;

Now run the form by pressing [F9], and notice that when the button is clicked the form caption and the button caption both change.

You can now experiment a little bit and learn how to use the standard components. To get started, I would recommend you to try samples of the following components:

## The Use of a Second Form

The tutorial shows how to use multiple forms in a project. In this example, only two forms, Form1 (main form) and Form2, are created, but the process is identical for additional forms.

There is a main form with a button, which when clicked opens the new form. The new form also receives a button which when clicked closes the new form and returns you to the main form.

If you have worked through the first tutorial The first GUI app, you will need to delete the code between the begin and end of procedure TForm1.Button1Click. Otherwise you will need to create a new project (application), drop a button on the form, and create the OnClick event handler for this Button1.
Click the new button to enter a caption (visible text on the button). To do this, select the button (just click it once) and in the Object Inspector click Properties -> Caption, and enter the text "Open Form2".

In the Main menu click File -> New Form, to add a second form (Form2) to the project. Place a button (Button1) on Form2 and create the OnClick event handler for it. Change the caption of this button to "Close".

Now the project has two forms, each of which can be selected and displayed with Main menu Project -> Forms (or key combination [Shift] + [F12]). Alternatively, you can select the tab for a Unit in the Source Editor, then use [F12] to switch between the code editor and form designer for the form of the associated Unit.

In the code editor, go to the Form1 associated Unit (Unit1) and add "Unit2" to the uses clause:

uses
Classes, SysUtils, ... , Unit2;  // It is important that the individual units are separated by a comma
// and the uses clause ends with a semicolon.

Now you can call Unit2 (and thus Form2) from Unit1.

Next, edit the OnClick event of the button belonging to Form1:

unit Unit1;
...
procedure TForm1.Button1Click(Sender: TObject);
begin
Form2.ShowModal;  //Displays Form2, the focus is placed on Form2.
end;
unit Unit2;
...
procedure TForm2.Button1Click(Sender: TObject);
begin
Close;  //Close Form2.
end;

Now you can start the project ( or [F9]) and open Form2 by clicking the button on Form1.

### Difference between Show and ShowModal

Both methods Show and ShowModal make a form visible. To see the difference between Show and ShowModal:

• Extend the previous example The use of a second form by adding a second TButton to Form1.
• Select Button1 and change the properties Name to btnShow and Caption to Show.
• Select Button2 and change the properties Name to btnShowModal and Caption to ShowModal.
• Create (or modify) the OnClick event handler of the two buttons as follows:
procedure TForm1.btnShowClick(Sender: TObject);
begin
Form2.Show;
ShowMessage('Form2 is opened!');
end;

procedure TForm1.btnShowModalClick(Sender: TObject);
begin
Form2.ShowModal;
ShowMessage('Form2 is opened and closed again!');
end;
• Start and watch the difference!
Show

This procedure makes a form visible and continues to execute the code of the calling control (Form1). In our example, the message (ShowMessage) appears almost simultaneously with Form2. You can also continue to use the calling form Form1. For example, it is possible to move it, or click the Show button again (but clicking ShowModal will cause an error).

Instead of using <myForm>.Show;, it is also possible to use <myForm>.Visible:=True;. The method Show does the following:

procedure TCustomForm.Show;
begin
Visible := True;
BringToFront;
end;

The only difference between <myForm>.Show;, and <myForm>.Visible:=True; is that the form displayed using Show will be on top of all other forms currently displayed.

ShowModal

ShowModal halts the processing of code in the calling control (Form1) until the newly opened form (Form2) has been closed. In the example, the ShowMessage line immediately following ShowModal is executed only after Form2 is closed. The calling form is frozen: You can neither move Form1 nor click any of its buttons.

ShowModal is a function that returns an integer result, see TModalResult. The returned value allows branching based on how the form was closed.

## Two Forms That Can Call Each Other

It is generally good program design to avoid calling the main form from a second form. It is better to return to the main form by closing the second form (as in the previous example) and letting focus revert to the main form. It is, however, possible to call the main from from a sub-form, as this example will show.

In order for Form1 to call Form2, Unit1 must have Unit2 in its Uses clause. Conversely, for Form2 to call Form1, Unit2 must have Unit1 in its Uses clause. This leads to a potential Circular Unit Reference compiler error, with each Unit referring to the other. This example also shows how to avoid the Circular Unit Reference error.

To set up this example, either modify the forms from the previous example (The Use of a Second Form), or create a new project with two forms, each having a single button. Set the caption of Form1.Button1 to "Open Form2", and set the caption of Form2.Button1 to "Open Form1".

If you are modifying the previous example, remove "Unit2" from the Uses clause in Unit1.

Add a Uses clause to the Implementation section of each Unit. Add Unit2 to the Unit1 clause, and add Unit1 to the Unit2 clause, as below:

unit Unit1;
...
implementation

uses
Unit2;
...
unit Unit2;
...
implementation

uses
Unit1;
...

Now change the code located behind the OnClick event of the button event handler:

unit Unit1;
...
procedure TForm1.Button1Click(Sender: TObject);
begin
Form2.Show;
end;
unit Unit2;
...
procedure TForm2.Button1Click(Sender: TObject);
begin
Form1.Show;
end;

## Passing Variables to Other Forms

In accordance with the above example The Use of a Second Form, it is possible to declare a global variable in the interface part of Unit2. This would allow access in both Unit1 and Unit2 to one and the same variable (This is because by putting Unit2 in the Uses clause of Unit1, all variables declared in the interface part of Unit2 are also available in Unit1). This practice should be limited to a minimum, as it quickly becomes difficult to remember which individual variables are in scope, potentially increasing errors. It is better to use local variables, define a Property in a Class or, alternatively, as a variable in a class.

In the next project, a second form is opened by clicking on the button. In this case, in the unit of the main form is counted how often the second shape has been shown. In this second form you can ask to see by clicking on the button, how often it has been opened:

• a new project with two forms, each a button on it and their OnClick events to evaluate.
• now, in the public part of the Class TForm2 (Unit2) a variable (in this case a constant, which we defined as variable abuse) of type integer with the name Count create:
unit Unit2;
...
TForm2 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ private declarations }
public
{ public declarations }
const Count: Integer = 0;   //here
end;
• now even customize the Button event handler accordingly:
unit Unit1;
...
procedure TForm1.Button1Click(Sender: TObject);
begin
inc(Form2.Count);  //Increase the counter by 1 on each call to Form2
Form2.ShowModal;
end;
unit Unit2;
...
procedure TForm2.Button1Click(Sender: TObject);
begin
ShowMessage('Form2 would be displayed '+IntToStr(Count)+' times');
end;

In this way you can in Unit1 access all public variables/properties/functions/procedures (general methods) of Unit2.

## Other Form-Related Subjects

### Use Another Form as the Main Form

If you determine after a while that you want to have displayed rather a different form or new form for the view at startup, you can under the main menu Project -> Project Options -> Forms:

Alternatively, you can display, in Mainmenu -> Project -> Show .lpr file, that Project.lpr (Pascal code of the main program) and create the first form to be displayed as the first:

program Project1;
...
Application.CreateForm(TForm2, Form2);  //Form2 is created in first and shown when the application starts
Application.CreateForm(TForm1, Form1);

## Generate the form dynamically

### Create a Lazarus designed form dynamically

You do not have to create all the forms that may be called during the term of an application at startup. Some developers generally keep none of it and delete the code automatically created when you insert a new form in a project from the Projekt.lpr out immediately. If you want to write a library that contains a couple of GUIs, you can not get around the dynamic creation of forms.

An example:

• new application with two forms, Form1 a button (add "Unit2" in the uses clause of unit1)
• open the Projekt.lpr (Project -> lpr file.)
• delete the line "Application.CreateForm(TForm2, Form2);"
• in the OnClick event of Button1, Form1 add following code:
procedure TForm1.Button1Click(Sender: TObject);
begin
Form2:=TForm2.Create(Nil);  //Form2 is created
Form2.ShowModal;            //Form2 is displayed
FreeAndNil(Form2);          //Free Form2
end;
• now simply start

### Creating a new form dynamically

The following example will demonstrate how new forms by hand the Form Designer, can be generated without.

With a button click, another form should open that contains a button which, when clicking a warning appears that the form will close and then the form is closed.

• New application with a form and a button
• In the OnClick event of Button1, Form1 add following code:
procedure TForm1.Button1Click(Sender: TObject);
var
MyForm: TForm;
MyButton: TButton;
begin
MyForm:=TForm.Create(nil);
MyForm.SetBounds(100, 100, 220, 150);
MyForm.Caption:='My dynamic created form';

MyButton:=TButton.create(MyForm);
MyButton.Caption:='Close my form';
MyButton.SetBounds(10, 10, 200, 30);
MyButton.Parent:=MyForm;

MyButton.OnClick:=@MyButtonClick;

MyForm.ShowModal;

FreeAndNil(MyForm);
end;

Note: If a component has been created with an owner (TButton.Create(Owner: TComponent)), it belongs to the owner, who is then responsible to free the component. Thus MyButton is freed automatically by freeing MyForm.

• now even the event handler of MyButtonClick must be created
• to this end, write in the class private section of TForm1 following procedure and press [Ctrl]+[Shift]+[C] (code completion):
TForm1 = class(TForm)
...
private
{ private declarations }
procedure MyButtonClick(Sender: TObject);
• and insert the following code there
procedure TForm1.MyButtonClick(Sender: TObject);
begin
Showmessage('Attention, my dynamically created form is closed!');
if Sender is TButton then
TForm(TButton(Sender).Parent).Close;
end;
• now the project can be compiled and executed

A few tips for manual generation of controls