AVR Embedded Tutorial - I²C, TWI/de

│ Deutsch (de) │ English (en) │

I²C / TWI

Vorwort

Dieser Code ist für einen Atmega328/Arduino mit 16MHz.

Wie man die UART ansteuert, steht hier:

• UART UARTInit und UARTSendString(...

Beschreibung

Dieses Beispiel demonstriert die Kommunikation mit der I²C/TWI - Schnittstelle.

Als Slave-Geräte werden 2 AD1115 A/D-Wandler verwendet. Diese sind sehr einfach in der Handhabung und sind auch sehr einfach erhältlich. Was sehr wichtig ist, dass man bei TWIStart die Adresse um ein Bit nach links verschiebt und anschließend mittels Write/Read mit or verknüpft. Es gibt viele Tutorials dazu. Dort sieht man das leider sehr schlecht.

PulUp-Widerstände sind nicht nötig, da diese schon auf der Platine des ADS1115 verbaut sind.

I²C Funktionen

Konstanten

const
  CPU_Clock = 16000000; // Taktfrequenz Arduino, default 16MHz.
  ADSaddr0  = $48;      // Adresse Wandler 0
  ADSaddr1  = $49;      // Adresse Wandler 1
  I2C_Takt  = 400000;   // I²C-Takt (400KHz)
  TWI_Write = 0;
  TWI_Read  = 1;

I²C inizialisieren

  procedure TWIInit;
  const
    TWBR_val = byte((CPU_Clock div I2C_Takt) - 16) div 2;
  begin
    TWSR := 0;
    TWBR := byte(TWBR_val);
  end;

I²C Senden/Empfangen starten

  procedure TWIStart(addr: byte);
  begin
    // Senden/Empfangen einleiten
    TWCR := 0;
    TWCR := (1 shl TWINT) or (1 shl TWSTA) or (1 shl TWEN);
    while ((TWCR and (1 shl TWINT)) = 0) do begin
    end;

    // Adresse des Endgerätes senden
    TWDR := addr;
    TWCR := (1 shl TWINT) or (1 shl TWEN);
    while ((TWCR and (1 shl TWINT)) = 0) do begin
    end;
  end;

I²C Senden/Empfang beendet

  procedure TWIStop;
  begin
    TWCR := (1 shl TWINT) or (1 shl TWSTO) or (1 shl TWEN);
  end;

Zeichen Senden

  procedure TWIWrite(u8data: byte);
  begin
    TWDR := u8data;
    TWCR := (1 shl TWINT) or (1 shl TWEN);
    while ((TWCR and (1 shl TWINT)) = 0) do begin
    end;
  end;

Zeichen Empfangen

Bis auf das vorletzte Zeichen muss mit TWIReadACK(... gelesen werden. Das letzte Zeichen muss mit TWIReadNACK(... gelesen werden.

  // Lesen bis zum vorletzten Zeichen.
  function TWIReadACK: byte;
  begin
    TWCR := (1 shl TWINT) or (1 shl TWEN) or (1 shl TWEA);
    while (TWCR and (1 shl TWINT)) = 0 do begin
    end;
    Result := TWDR;
  end;

  // Letztes Zeichen lesen.
  function TWIReadNACK: byte;
  begin
    TWCR := (1 shl TWINT) or (1 shl TWEN);
    while (TWCR and (1 shl TWINT)) = 0 do begin
    end;
    Result := TWDR;
  end;

  Hinweis: Anmerkung: Diese Funktionen bleibt bei einem Hardware-Fehler, oder die Slave-Adresse falsch ist, hängen !

Zeichen Empfangen mit Fehlerabfrage

Das diese Funktionen nicht hängen bleiben, muss man in der while-Schleife einen Zähler einbauen.

Wen der Zähler 255 erreicht, wird die Schleife unterbrochen und ein Fehler ausgegeben.

255 wird erreicht, wen an der I²C-Adresse kein Gerät gefunden wird.

// Lesen bis zum vorletzten Zeichen.
function TWIReadACK_Error: byte;
var
  err:byte;
begin
  err := 0;
  TWCR := (1 shl TWINT) or (1 shl TWEN) or (1 shl TWEA);
  while ((TWCR and (1 shl TWINT)) = 0) and (err < 255) do begin
    Inc(err);
  end;
  if err = 255 then begin
    UARTSendString('I²C-Timeout');
    Result := 0;
  end else begin
    Result := TWDR;
  end;
end;

// Letztes Zeichen lesen.
function TWIReadNACK_Error: byte;
var
  err:byte;
begin
  err := 0;
  TWCR := (1 shl TWINT) or (1 shl TWEN);
  while ((TWCR and (1 shl TWINT)) = 0) and (err < 255) do begin
    Inc(err);
  end;
  if err = 255 then begin
    UARTSendString('I²C-Timeout');
    Result := 0;
  end else begin
    Result := TWDR;
  end;
end;

ADS1115 spezifischen Code

Dieser Code ist ADS1115 spezifischen, andere I²C-Geräte müssen im Datenblatt nachgeguckt werden.

  // Parameter an ADS1115 schicken und Messen einleiten
  procedure WriteADS1115(addr: UInt16);
  begin
    TWIStart((addr shl 1) or TWI_Write);
    TWIWrite(1);
    TWIWrite(%11000011);  // High
    TWIWrite(%11100011);  // Low
    TWIStop;
  end;

  // Messung von ADS1115 auslesen.
  function ReadADS1115(addr: UInt16): UInt16;
  begin
    TWIStart((addr shl 1) or TWI_Write);
    TWIWrite(0);
    TWIStop;

    TWIStart((addr shl 1) or TWI_Read);
    Result := TWIReadACK * $100 + TWIReadNACK;
    TWIStop;
  end;

Beispiel

var
  Data: Integer;
  s:    ShortString;

begin
  asm cli end; // Interrupt sperren.
  UARTInit;
  TWIInit;
  asm sei end; // Interrupt frei geben.

  repeat
    WriteADS1115(ADSaddr0);
    Data := ReadADS1115(ADSaddr0);

    str(Data: 6, s);
    UARTSendString('Kanal 0: ');
    UARTSendString(s);

    WriteADS1115(ADSaddr1);
    Data := ReadADS1115(ADSaddr1);

    str(Data: 6, s);
    UARTSendString(' Kanal 1: ');
    UARTSendString(s);
    UARTSendString(#13#10);
  until 1 = 2;
end.

Parameter ADS1115

Eine Auflistung der Parameter des ADS1115. Mehr Infos im Datenblatt.

Bit-Belegung des ADS1115:

Low: 11100011 High: 11000011

Bit	Bezeichnung	Beschreibung
15	OS: Operational status or single-shot conversion start	0 : no effect 1 : Start a single conversion (when in power-down state)
14:12	MUX[2:0]: Input multiplexer configuration (ADS1115 only)	000 : AINP = AIN0 and AINN = AIN1 (default) 001 : AINP = AIN0 and AINN = AIN3 010 : AINP = AIN1 and AINN = AIN3 011 : AINP = AIN2 and AINN = AIN3 100 : AINP = AIN0 and AINN = GND 101 : AINP = AIN1 and AINN = GND 110 : AINP = AIN2 and AINN = GND 111 : AINP = AIN3 and AINN = GND
11:9	PGA[2:0]:Programmable gain amplifier configuration	000 : FSR = ±6.144 V 001 : FSR = ±4.096 V 010 : FSR = ±2.048 V (default) 011 : FSR = ±1.024 V 100 : FSR = ±0.512 V 101 : FSR = ±0.256 V 110 : FSR = ±0.256 V 111 : FSR = ±0.256 V
8	MODE: Device operating mode	0 : Continuous-conversion mode 1 : Single-shot mode or power-down state (default)
7:5	DR[2:0]: Data rate	000 : 8 SPS 001 : 16 SPS 010 : 32 SPS 011 : 64 SPS 100 : 128 SPS (default) 101 : 250 SPS 110 : 475 SPS 111 : 860 SPS
4	COMP_MODE: Comparator mode	0 : Traditional comparator (default) 1 : Window comparator
3	COMP_POL: Comparator polarity	0 : Actice low (default) 1 : Actice high
2	COMP_LAT: Latching comparator	0 : Nonlatching comparator (default) 1 : Latching comparator
1:0	COMP_QUE[1:0]: Comparator queue and disable	00 : Assert after one conversion 01 : Assert after two conversions 10 : Assert after four conversions 11 : Disable comparator and set ALERT/RDY pin to high-impedance (default)

Siehe auch

• Übersichtseite AVR Embedded Tutorial

Autor: Mathias