Lazarus Tdbf Tutorial/es

From Lazarus wiki
Jump to navigationJump to search

Deutsch (de) English (en) español (es) français (fr) português (pt) русский (ru) 中文(中国大陆)‎ (zh_CN)


Resumen

   Este tutorial trata sobre el desarrollo elemental de bases de datos usando el componente TDbf (de Micha Nelissen) con Lazarus. Hay disponible documentación adicional para TDbf. Esta página fue creada por Tony Maro, pero ¡se agradecen otras colaboraciones!

Lo que necesitarás

 Sin duda pronto será más fácil cuando aparezca la próxima versión 2.0 de Free Pascal, sin embargo, entre tanto, necesitará una versión reciente de CVS de FPC 1.9.X para usar adecuadamente el componente TDbf. Se puede descargar sólo el componente TDbf y usarlo con la versión 1.1 de FreePascal, sin embargo, este documento fue escrito pensando en la 1.9.X, en parte debido a correcciones en otros componentes de bases de datos usados en Lazarus.    (Nota del revisor: desde 2007/09/10 está disponible la versión 2.2.0 de FPC. LA RC1 de la 2.2.2 está disponible para pruebas)

   También necesitará instalar el paquete DbfLaz que trae Lazarus. Está situado en la carpeta lazarus/components/tdbf/.

¿Qué se puede hacer con TDbf?

   El componente TDbf proporciona a Lazarus (y otros entornos) acceso a tablas dBase y FoxPro. Permite la lectura, escritura y creación de tablas dBase III+, dBase IV, Visual dBase VII y FoxPro. Y sin necesitar librerías o gestores de bases de datos adicionales. Simplemente ponga el componente TDbf en su formulario y tendrá acceso inmediato a un entorno de bases de datos de para múltiples plataformas. TDbf funciona tanto en Windows como en Linux usando Lazarus.

Cómo crear una nueva tabla

   Como no hay todavía una aplicación "Database Desktop" para Lazarus, debemos crear las tablas de la base de datos mediante código, o utilizando herramientas externas.

Establecer la ruta de acceso

   Es recomendable crear una carpeta para sus aplicaciones de bases de datos. Esto simplifica la realización de copias de seguridad de los datos. Hay dos maneras de establecer la ruta de acceso. Puede fijar la ruta completa usando la propiedad FilePathFull, o puede establecer una ruta relativa a la ruta del programa con FilePath. Por ejemplo, estableciendo "FilePath" en tiempo de ejecución a "datos/" utilizaría una subcarpeta de datos dentro de la carpeta del archivo ejecutable. Fijar la propiedad "FilePathFull" a "/var/datos/" colocaría todo en esa carpeta, no teniendo en cuenta la ubicación del programa.

Eligir un tipo de tabla con TableLevel

   Por omisión, TDbf creará tablas dBase IV. Aunque son muy compatibles, hay características que puede desear usar que no están disponibles. Para poder utilizar campos autoincrementales, debe usar algo más nuevo. Los tipos de tabla posibles son:

  • 3 dBase III+
  • 4 dBase IV
  • 7 Visual dBase VII
  • 25 FoxPro

   Para elegir un tipo de tabla seleccione apropiadamente la propiedad TableLevel.

Añadir campos

   La creación de campos para su nueva tabla en tiempo de ejecución se realiza como en Delphi. Una vez establecidas las propiedades FilePath, TableLevel, y TableName, hay que utilizar la propiedad FieldDefs para determinar su estructura. Por ejemplo: <delphi> MyDbf.FilePathFull := '/ubicacion/para/mis/datos';

MyDbf.TableLevel := 7;
MyDbf.TableName := 'clientes.dbf'; // nota: ¿es realmente necesario .dbf?
With MyDbf.FieldDefs do begin
  Add('Id', ftAutoInc, 0, True);
  Add('Nombre', ftString, 80, True);
End;</delphi>

   Los tipos de campo definidos son:

  • ftUnknown
  • ftString
  • ftSmallInt
  • ftInteger
  • ftWord
  • ftBoolean
  • ftFloat
  • ftCurrency (TableLevel 25)
  • ftBCD (TableLevel 25)
  • ftDate
  • ftTime
  • ftDateTime
  • ftBytes (TableLevel 25)
  • ftVarBytes
  • ftAutoInc (TableLevel 7 or 25)
  • ftBlob
  • ftMemo
  • ftGraphic
  • ftFmtMemo
  • ftParadoxOle
  • ftDBaseOle
  • ftTypedBinary
  • ftCursor
  • ftFixedChar
  • ftWideString
  • ftLargeInt
  • ftADT
  • ftArray
  • ftReference
  • ftDataSet
  • ftOraBlob
  • ftOraClob
  • ftVariant
  • ftInterface
  • ftIDispatch
  • ftGuid
  • ftTimeStamp
  • ftFMTBcd

   Los tipos que aparecen en negrita son los soportados en la actualidad.

¡Siga adelante y créela!

   Una vez que ha definido los campos deseará usarlos en su nueva tabla, puede seguir adelante y crearla con: <delphi> MyDbf.CreateTable;</delphi>

Añadir índices a una tabla

   Si su base de datos es bastante grande, deberá definir índices para hacer búsquedas más rápidas. Para cambiar la estructura de índices de una tabla, deberemos tener acceso exclusivo a la tabla -mientras los creamos.

<delphi> MyDbf.Exclusive := True;

MyDbf.Open;</delphi>

   Justo ahora, tenemos que añadir el índice.

<delphi> MyDbf.AddIndex('clienteid', 'Id', [ixPrimary, ixUnique]);

MyDbf.AddIndex('nombrecliente','Nombre', [ixCaseInsensitive]);
MyDbf.Close;</delphi>

Lo unimos todo y ... ¡ya está!

   El siguiente ejemplo crea una tabla "clientes" mediante código. Esto, por supuesto, sólo es necesario hacerlo una vez para cada tabla, y de ahí en adelante, abrir la tabla, no crearla ;-)

<delphi> { Necesitamos que las siguientes unidades aparezcan en la clásula USES:}

uses {otras unidades, } Dbf, db, Dbf_Common;
{ "Dbf" aparecerá, automáticamente, cuando pongamos el componente TDbf en el formulario...   }
{ pero necesitamos la unidad "db" para el objeto DataSet
{ y la unidad "Dbf_Common" para las definiciones de tipos de campo, por ejemplo        }
var
  MyDbf: TDbf;
begin
  MyDbf := TDbf.Create(nil);
  try
    
    MyDbf.FilePath := 'datos/';    // usamos una ruta de acceso relativa para la carpeta "datos" 
    MyDbf.TableLevel := 7;         // utilizaremos tablas de tipo "Visual dBase VII"
    MyDbf.Exclusive := True;       // imprescindible para poder modificar la estructura añadiendo campos
    MyDbf.TableName := 'clientes.dbf';
    With MyDbf.FieldDefs do begin
      Add('Id', ftAutoInc, 0, True);
      Add('Nombre', ftString, 80, True);
    End;
    MyDbf.CreateTable;
    MyDbf.Open;
    MyDbf.AddIndex('clienteid', 'Id', [ixPrimary, ixUnique]);
    { añadimos un índice secundario }
    MyDbf.AddIndex('nombrecliente','Nombre', [ixCaseInsensitive]);
    MyDbf.Close;
  finally
    MyDbf.Free;
  end;
end;</delphi>

Archivos índice externos

   El componente TDBF también soporta índices secundarios que se almacenan en un archivo separado. Esto será útil cuándo la base de datos sea muy grande, al poder separar en varios archivos los distintos índices. Los archivos de índice secundarios se crean de forma muy parecida a los índices normales, pero con la adición de la extensión '.ndx ' en el nombre:

<delphi> MyDbf.AddIndex('nombrecliente.ndx','Nombre', [ixCaseInsensitive]);</delphi>    Estos índices no se gestionan de forma automática, por ello cada vez que se abre la tabla, se deberán cargar los archivos de índice que deseamos utilizar, usando el método OpenIndexFile, así: <delphi> MyDbf.OpenIndexFile('nombrecliente.ndx');</delphi>    Por la misma razón los índices se empaquetan por separado, para ello utilizaremos el método CompactIndexFile, de esta forma: <delphi> MyDbf.CompactIndexFile('nombrecliente.ndx');</delphi>    Y al dar el valor a la propiedad IndexName, para seleccionar el que estará activo, debemos incluir el nombre y la extensión: <delphi> MyDbf.IndexName := 'nombrecliente.ndx';</delphi>

Cómo enlazar TDbf a componentes de datos

   Los ejemplos anteriores muestran como crear una nueva tabla de base de datos mediante código. Usar la tabla es aún más simple.

   Los componentes de acceso a datos en Lazarus (como el control de TDBEDIT) se vinculan a un componente TDataSource mediante las propiedades DataSource y DataField. El componente TDataSource controla la comunicación entre el gestor de bases de datos y los componentes de acceso a datos. Un TDataSource entonces se vincula al componente TDbf mediante su propiedad "DataSet". La conexión es algo así:

 TDbEdit------\
              |
 TDbEdit------|-->TDataSource-->TDbf
              |
 TDbNavigator-/

   No olvide establecer las propiedades FilePath (o FilePathFulll), TableLevel, y TableName del componente TDbf a los valores adecuados antes de la llamada

<delphi> TDbf.Active := True;</delphi>

   Se podría decir mucho más sobre programación con bases de datos en Lazarus, y yo recomendaría un buen libro de programación de bases de datos con Delphi porque los conceptos fundamentales son los mismos. Constantemente hago referencia a mi ejemplar de "Liberado Delphi 2" porque los conceptos y el código básico no han cambiado mucho en 8 años.

Empaquetar y reconstruir índices

   Cuando se borra un registro, realmente no desaparece físicamente del archivo que guarda la tabla. De vez en cuando debe empaquetar la tabla para eliminar realmente los registros y así recuperar ese espacio desaprovechado del archivo. Esto hay que hacerlo teniendo la tabla abierta en modo exclusivo.

<delphi> MyDbf.Exclusive := True;

MyDbf.Open;
MyDbf.PackTable;
// reconstruimos todos los índices
MyDbf.RegenerateIndexes;
MyDbf.Close;
MyDbf.Exclusive := False;</delphi>

Relaciones de tabla principal

   La verdadera potencia de la programación de bases de datos comienza cuando tenemos múltiples tablas que se hacen referencia mutuamente. Mientras que TDbf aún no soporta la integridad referencial, si soporta una relación del tipo maestro/detalle entre componentes TDbf.

   Cuando hay dos tablas relacionadas, por ejemplo:

 [clientes]
 Id       <----\
 Nombre        |
 Telefono      |
 Direccion     |
               |  ClienteID en facturas hace referencia un campo primario de clientes
 [facturas]    |
 Id            |
 Importe       |
 ClienteID   --\---|  * Campo indexado como "idxclienteid"

   Si desea mostrar todas las facturas para un cliente determinado, la tabla detalle (facturas) puede sincronizarse con la tabla principal (clientes) automáticamente.

   En el componente TDbf de facturas seleccione lo siguiente:

<delphi> InvDbf.IndexName := 'idxclienteid'; // campo que se emparejará con el campo ID de la tabla clientes

InvDbf.MasterSource := dsClientes;  // fuente de datos que se enlaza al componente TDbf de clientes
InvDbf.MasterFields := 'Id';        // campo en la tabla clientes que emparejamos con nuestro índice</delphi>

Programa de ejemplo - navegador DB

   He escrito un programa sencillo que utiliza el componente TDbf para abrir y mostrar tablas de bases de datos mediante el control dbGrid. El ejecutable Linux, junto con las fuentes del proyecto, que debería compilarse bien en Windows, está disponible en

 tony.maro.net

A tener en cuenta

   Actualmente no se soporta la integridad referencial, ni los archivos .db encriptados internamente.