MySQLDatabases/de

From Lazarus wiki
Jump to navigationJump to search

Deutsch (de) English (en) français (fr) 日本語 (ja) polski (pl) slovenčina (sk)

Work in progress

Einleitung

Im Datenbank Tutorial sahen wir einen ersten Versuch, eine Verbindung zu einem MySQL Server herzustellen. Wir verwendeten keine Komponenten, weder visuelle oder nichtvisuelle zu diesem Zeitpunkt. Hier soll erklärt werden, wie man sich auf eine (vielleicht) einfachere Weise mit einem MySQL Server verbindet.

Verfügbare Komponenten

MySQL Komponenten

Das /components/mysql Verzeichnis wurde in Version 0.9.13 entfernt. Weichen sie auf das sqldblaz Package aus.

Wenn sie in das $Lazarus/components/mysql Verzeichnis schauen, dann werden sie zwei Lazarus Packages finden. Es gibt ein Package für MySQL Version 3.2x (mysql3laz.lpk) und eines für MySQL Version 4.x (mysql4laz.lpk). Falls noch nicht geschehen, installieren sie das entsprechende Package, abhängig von der Server Version. Denken sie daran, daß es nicht möglich ist, das Packages für Version 3 zu verwenden für eine Verbindung mit einem Server der Version 4 und umgekehrt. Wenn sie dieses Package installiert haben werden sie einen neuen Tab sehen in der Komponentenpalette, genannt MySQL. Auf diesem Tab gibt es zwei Komponenten, TMySQLDatabase und TMySQLDataset.

Übrigens - bevor sie versuchen, diese Komponenten in Lazarus zu installieren stellen sie sicher, daß sie die entsprechenden MySQL Client Bibliotheken haben, oder Lazarus wird nach der Installation nicht starten.

SQLdb Komponenten

Eine andere Möglichkeit ist die Installation des Packages im $Lazarus/components/sqldb Verzeichnis. In diesem Verzeichnis können sie eine Packagedatei mit Namen sqldblaz.lpk sehen. Sie müssen dieses Package installieren und das mysql4connlaz.lpk Package aus dem $Lazarus/components/sqldb/mysql Verzeichnis. Das erste Package enthält einige allgemeine Komponenten, die für alle Datenbanken verwendet werden. Diese Komponenten sind TSQLTransaction und TSQLQuery und sind zu finden auf dem neuen SQLdb Tab. Nach der Installation von mysql4connlaz.lpk werden sie eine dritte Komponente auf dem SQLdb Tab finden mit Namen TMySQLConnection (dargestellt durch einen Delphin).

Wenn sie das Verzeichnis $Lazarus/components/sqldb/mysql nicht finden können und mysql4connlaz.lpk dann bedeutet dies, daß sie eine neuere Version benutzen, in welcher mysql4connlaz.lpk fusioniert wurde mit sqldblaz.lpk. Das ist OK, die Installation von sqldblaz.lpk wird ihnen alle erwähnten Komponenten bieten im selben Lazarus IDE toolbar TAB.

Wenn sie nicht wissen, wie man Komponenten / Packages installiert, dann schauen sie auf dieser Seite nach. Da die SQLdb Komponenten allgemeiner sind und auch für andere Datenbanken verwendet werden können, indem man zum Beispiel TMySQLConnection durch TIBConnection ersetzt, werden wir ein Programm entwickeln mit den SQLdb Komponenten.

Übrigens - (und das ist ziemlich wichtig!) die SQLdb Komponenten können nur die MySQL Client Bibliotheken Version 4.0 verwenden, andere Versionen wie 3.x, 4.x, etc. werden nicht funktionieren! Aber Anwendungen sollten in der Lage sein, eine Verbindung zu einem MySQL Server jeglicher Version herzustellen.

Erläuterung der verwendeten Komponenten

TMySQLConnection

Die TMySQLConnection wird verwendet um Parameter aufzubewahren für die Verbindung zum Datenbank Server. Sie erlaubt ihnen to set the host to connect to and the userid and password to use in the connection. Eine andere Eigenschaft von TMySQLConnection wird verwendet, um to indicate die Datenbank, die sie verwenden wollen. The 'LoginPrompt' is not functional yet, so make sure that next to the HostName und DatabaseName die UserName und Password Eigenschaften ebenso Werte haben bevor sie versuchen, die Verbindung zu öffnen. Stellen sie sicher auch eine TSQLTransaction zu verwenden und sie mit ihrer MySQLConnection zu verbinden durch setzen der Transaction Eigenschaft, oder sie werden nicht in der Lage sein, ein SQLQuery zu öffnen.

Anmerkung. In der neuesten SVN Version von Lazarus finden sie 3 MySQLConnection Komponenten. Dies sind TMySQL40Connection, TMySQL41Connection und TMySQL50Connection. Stellen sie sicher, daß sie die richtige verwenden zum Verbinden mit ihrem Server. Wenn z.B. bei ihnen MySQL 4.1 läuft, dann verwenden sie TMySQL41Connection.

TSQLTransaction

Eine SQLTransaction wird für die interne Organisation benötigt. Eine SQLTransaction wird automatisch aktiviert, wenn sie ein Dataset öffnen, welches diese benutzt. Wenn sie aber die SQLConnection schließen wollen, müssen sie zuerst sicherstellen, daß die SQLTransaction nicht aktiv ist.

TSQLQuery

TSQLQuery wird verwendet, um SQL Anweisungen auf dem Server auszuführen. Sie können Daten abrufen, indem sie die SQL Eigenschaft auf einige SELECT Anweisungen setzen und die Open Methode aufrufen. Oder sie können Daten manipulieren, indem sie einige INSERT, DELETE oder UPDATE Anweisungen erstellen. Im letzteren Fall sollten sie nicht die Open Methode benutzen sondern die ExecSQL Methode.

TDataSource

Ein TDataSource bietet die Verbindung zwischen den sichtbaren datensensitiven Komponenten wie DBEdit, DBGrid und einem TDataset. Es macht die Daten für die datensensitiven Komponenten verfügbar zum Anzeigen. Ein TDatasource kann nur mit einem einzigen Dataset verbunden werden zur selben Zeit, aber es können mehrere datensensitive Komponenten verbunden werden.

TDBGrid

Ein DBGrid kann benutzt werden, um die Daten zu präsentieren, die man von einem Dataset erhalten hat. Das DBGrid benötigt eine Datasource für die Verbindung zu einem Dataset. Wenn das Dataset geöffnet wird, dann wird das DBGrid automatisch mit den Daten bestückt.

Unser Programm

Die Grundlagen

Wir werden versuchen, ein Programm zu erstellen, das auf diesem hier (auf holländisch) basiert, welches auf dem Original (auf englisch) von Chris basiert.

Das Hauptformular

Wir werden den selben Hauptbildschirm verwenden und die gesamte Funktionalität von Anfang an erstellen :) Wie sie sehen werden gibt es a lot less to take care of, because the components really take away all the hard stuff! So lets start by making a screen that looks like this.
Trymysql.png
Vom SQLdb-Tab platzieren sie eine TMySQLConnection, eine TSQLTransaction und eine TSQLQuery Components.png auf diesem Formular. Ändern sie nicht die vorgegebenen Namen dieser Komponenten. Ausgenommen die Connection Komponente. Um diesen Artikel für alle Versionen von MySQL verwenden zu können, benennen sie ihre MySQL??Connection Komponente in MySQLConnection1 um. Wir müssen diese Komponenten miteinander verbinden, damit sie ihren Job erledigen können. Daher müssen die folgenden Eigenschaften gesetzt werden:

Komponente Eigenschaft Wert
MySQLConnection1 Transaction SQLTransaction1
SQLTransaction1 Database MySQLConnection1
SQLQuery1 Database MySQLConnection1
SQLQuery1 Transaction SQLTransaction1

Die Transaction-Eigenschaft von SQLQuery1 wird automatisch gesetzt, wenn sie zuerst die Transaction-Eigenschaft von MySQLConnection1 setzen. Wenn sie diese setzen, dann werden sie feststellen, daß SQLTransaction1.Database auf MySQLConnection1 gesetzt wurde.

Der Code

Wie sie in der Bildschirmanzeige sehen können, sind beim Start des Programms nur die Schaltflächen "Connect to server" und "Exit" verfügbar. Um mit den anderen Schaltflächen arbeiten zu können benötigen wir weitere Informationenen, daher sind sie gesperrt. Wir könnten auch entscheiden, "Connect to Server" ebenfalls zu sperren, bis die Informationen für host, username und password eingegeben wurden. Ich habe mich dagegen entschieden, weil unser Benutzer denken könnte: "Nichts scheint möglich zu sein, ich drücke auf Exit." :)

Bevor ich damit beginne, ihnen den Code mitzuteilen, möchte ich betonen, daß es mehr Fehlerbehandlung im Code geben sollte. Kritische Abschnitte sollten platziert werden in

try ... finally

oder

try ... except

Konstruktionen.

Verbinden mit einem Server

Das erste was wir tun müssen, ist eine Verbindung zum Server herzustellen. As when connecting we don't know welche Datenbanken auf dem Server verfügbar sind we will ask for a list of databases on connecting. However there is one catch, to make the connection we have to enter einen gültigen DatabaseName in den Eigenschaften von MySQLConnection. Sie werden im Code sehen, daß ich die "mysql" Datenbank verwende. Diese Datenbank wird von MySQL zur Organisation verwendet und wird daher immer da sein.

procedure TFormTryMySQL.ConnectButtonClick(Sender: TObject);
begin
  // Prüfen ob wir eine aktive Verbindung haben. Falls ja, schliessen wir sie.
  if MySQLConnection1.Connected then CloseConnection(Sender);
  // Die Verbindungsparameter setzen.
  MySQLConnection1.HostName := HostEdit.Text;
  MySQLConnection1.UserName := UserEdit.Text;
  MySQLConnection1.Password := PasswdEdit.Text;
  MySQLConnection1.DatabaseName := 'mysql'; // MySQL ist immer vorhanden!
  ShowString('Opening a connection to server: ' + HostEdit.Text);
  MySQLConnection1.Open;
  // Zuerst eine Liste der verfügbaren Datenbanken abfragen.
  if MySQLConnection1.Connected then begin
    ShowString('Connected to server: ' + HostEdit.Text);
    ShowString('Retrieving list of available databases.');
    SQLQuery1.SQL.Text := 'show databases';
    SQLQuery1.Open;
    while not SQLQuery1.EOF do begin
      DatabaseComboBox.Items.Add(SQLQuery1.Fields[0].AsString);
      SQLQuery1.Next;
    end;
    SQLQuery1.Close;
    ShowString('List of databases received!');
  end;
end;

Zuerst prüfen wir, ob wir mit einem Server verbunden sind. Falls ja, dann rufen wir eine private Methode "CloseConnection" auf. In dieser Methode some more housekeeping is done like disabling buttons and clearing comboboxes and listboxes. Dann setzen wir die notwendigen Parameter für die Verbindung zum Server.

Überall in unserem Programm werden sie Aufrufe von ShowString sehen. Diese Methode fügt eine Zeile zu dem Memo auf unserem Formular hinzu which acts like a kind of log.

Mit der Parameterzusammenstellung können wir mit dem Server verbinden. Dies wird erreicht durch den Aufruf von

MySQLConnection1.Open;

In einer ordentlichen Anwendung würde man dies in eine Ausnahmebehandlungskonstruktion platzieren, um dem Benutzer eine freundliche Botschaft zu präsentieren, falls die Verbindung fehlgeschlagen ist. Wenn wir verbunden sind, wollen wir eine Liste der Datenbanken vom Server erhalten. Um die Daten vom Server zu erhalten wird eine TSQLQuery verwendet. Die SQL Eigenschaft wird verwendet, um die SQL-Anweisung aufzubewahren, die an den Server gesendet wird. MySQL kennt das SHOW DATABASES Kommando, um die Liste der Datenbanken zu erhalten. Nachdem wir den SQL-Text eingegeben haben, rufen wir

SQLQuery1.Open;

auf. Die Ergebnismenge einer SQLQuery kann geprüft werden durch die fields Eigenschaft. Wie sie sehen können iterieren wir durch die Datensätze durch aufrufen von

SQLQuery1.Next;

Wenn wir alle verfügbaren Datenbanken zu unserer Combobox hinzugefügt haben, schließen wir die SQLQuery wieder.

Auswahl einer Datenbank

Wenn der Benutzer eine Datenbank in der DatabaseComboBox auswählt, aktivieren wir den "Select Database" Button. In dem OnClick Ereignis dieses Buttons setzen wir DatabaseName der MySQLConnection1, und fordern eine Liste der Tabellen an. Die letzte Anweisung dieser Prozedur aktiviert den "Open Query" Button, so daß der Benutzer eine Abfrage in der "Command" Editbox eingeben kann und diese an den Server sendet.

procedure TFormTryMySQL.SelectDBButtonClick(Sender: TObject);
begin
  // Eine Datenbank wurde ausgewählt, lassen sie uns die Tabellen darin abfragen.
  CloseConnection(Sender);
  if DatabaseComboBox.ItemIndex <> -1 then begin
    with DatabaseComboBox do
      MySQLConnection1.DatabaseName := Items[ItemIndex];
    ShowString('Retreiving list of tables');
    SQLQuery1.SQL.Text := 'show tables';
    SQLQuery1.Open;
    while not SQLQuery1.EOF do begin
      TableComboBox.Items.Add(SQLQuery1.Fields[0].AsString);
      SQLQuery1.Next;
    end;
    SQLQuery1.Close;
    ShowString('List of tables received');
  end;
  OpenQueryButton.Enabled := True;
end;

MySQL hat ein spezielles Kommando, um eine Liste der Tabellen zu erhalten, vergleichbar dem Erhalten einer Liste der Datenbanken, show tables. Das Ergebnis dieser Abfrage wird auf die selbe Weise gehandhabt wie die Liste der Datenbanken und alle Tabellen werden zur TableComboBox hinzugefügt. Sie wundern sich vielleicht, warum wir die Verbindung nicht erneut öffnen bevor wir die Abfrage auslösen? Nun, dies wird automatisch erledigt (falls notwendig), wenn wir die SQLQuery aktivieren.

Felder in einer Tabelle

In MySQL können sie erneut eine Form von "SHOW" verwenden, um die Felder in einer Tabelle zu erhalten. In diesem Fall "SHOW COLUMNS FROM <Tabellenname>". Wenn der Benutzer eine Tablle aus der TableComboBox auswählt wird das OnChange Ereignis dieser ComboBox ausgelöst, welches die FieldListbox füllt.

procedure TFormTryMySQL.TableComboBoxChange(Sender: TObject);
begin
  FieldListBox.Clear;
  SQLQuery1.SQL.Text := 'show columns from ' + TableComboBox.Text;
  SQLQuery1.Open;
  while not SQLQuery1.EOF do begin
    FieldListBox.Items.Add(SQLQuery1.Fields[0].AsString);
    SQLQuery1.Next;
  end;
  SQLQuery1.Close;
end;

Ebenso wie die Namen der Felder, enthält die Ergebnismenge Informationen über den Typ des Feldes, ob das Feld ein Schlüssel ist, ob Nullwerte erlaubt sind und einiges mehr.

Anzeigen der Daten

Wie wir bereits sagten wollen wir Komponenten verwenden, um eine Verbindung zur Datenbank zu bekommen. Lassen sie uns ebenso einige Komponenten verwenden, um die Daten zu zeigen. Wir werden ein zweites Formular verwenden, um ein grid zu zeigen, mit den vom Benutzer angeforderten Daten. Dieses Formular wird gezeigt, wenn der Benutzer ein SQL Kommando im "Command" editbox eingegeben und danach auf den "Open Query" Button geklicht hat. Dies ist das OnClick Ereignis:

procedure TFormTryMySQL.OpenQueryButtonClick(Sender: TObject);
begin
  ShowQueryForm := TShowQueryForm.Create(self);
  ShowQueryForm.Datasource1.DataSet := SQLQuery1;
  SQLQuery1.SQL.Text := CommandEdit.Text;
  SQLQuery1.Open;
  ShowQueryForm.ShowModal;
  ShowQueryForm.Free;
  SQLQuery1.Close;
end;

Das ShowQuery Formular sieht etwa so aus:

Mysqlshow.png

und enthält ein

TPanel Align alBottom
TDataSource
TDBGrid Align alClient
DataSource DataSource1
TButton Caption Close

Der Button wird auf dem Panel plaziert. Was im "Open Query" OnClick Ereignis passiert ist folgendes. Zuerst erzeugen wir eine Instanz von TShowQueryForm. Zweitens setzen wir die DataSet Eigenschaft der DataSource auf unsere SQLQuery1. Dann setzen wir das SQLQuery SQL Kommando auf die Benutzereingabe in der "Command" editbox und öffnen es. Dann wird das ShowQuery Formular modal gezeigt, this means that it will have the focus of our application until it is closed. Wenn sie geschlossen wird, geben wir sie "frei" und schließen SQLQuery1 erneut.

Quellen

Die Quellen für dieses Projekt können von hier heruntergeladen werden. Für mehr Demoprojekte siehe Sourceforge.