SqlDBHowto/es

│ Deutsch (de) │ English (en) │ español (es) │ français (fr) │ 日本語 (ja) │ Nederlands (nl) │ polski (pl) │ 中文（中国大陆）‎ (zh_CN) │

Introducción

   Este texto se configura como un "cómo-hacer". Pretende responder a una serie de preguntas una por una, explicando cómo se pueden utilizar las distintas clases. Todas estas cuestiones puestas una detrás de otra forman una especie de tutoría.

   Voy a tratar de esccribir de tal manera que el texto pueda ser utilizado para Lazarus, así como FreePascal. Sin embargo, los ejemplos son para FreePascal (es decir, son aplicaciones de consola)

¿Cómo conectarse a un servidor de base de datos?

   SQLdb no se conecta a un servidor de base de datos directamente sino que utiliza el cliente correspondiente al servidor de base de datos utilizado. SQLdb envía los comandos a la librería de cliente, la cual se conecta a la base de datos y le pasa los comandos. Esto significa que una librería de cliente debe ser instalada en el equipo para establecer una conexión con una base de datos. En Windows un cliente suele ser una .dll, bajo Linux un .so y bajo OS/X una .dylib.

   Cuando la librería de cliente se ha instalado correctamente puede conectarse a un servidor de base de datos utilizando un componente TSQLConnection. Hay disponibles componentes TSQLConnection para diferentes servidores de base de datos ( ver paquete SQLdb) - siendo el listado de las disponibles el siguiente:

• Firebird/Interbase: TIBConnection ( ver enlace)
• MS-SQL: TMSSQLConnection (disponible desde la versión 2.6.1 de FPC,ver enlace)se puede crear una conexión con el método open. Si
• MySQL v4.0: TMySQL40Connection (ver enlace)
• MySQL v4.1: TMySQL41Connection (ver enlace)
• MySQL v5.0: TMySQL50Connection (ver enlace)
• MySQL v5.1: TMySQL51Connection (disponible desde la versión 2.5.1 de FPC,ver enlace)
• MySQL v5.5: TMySQL55Connection (disponible desde la versión 2.?.? ver enlace)
• ODBC: TODBCConnection (ver enlace)
• Oracle: TOracleConnection (Oracle)
• PostgreSQL: TPQConnection (ver enlace)
• Sqlite3: TSQLite3Connection (disponible desde la versión 2.2.2 de FPC, ver enlace)
• Sybase ASE: TSybaseConnection (disponible desde la versión 2.6.1 de FPC, ver enlace)

   Las diferencias entre las versiones de cliente MySQL son grandes, en la medida que los clientes y las conexiones no se pueden intercambiar. Con un cliente MySQL versión 4.1 instalado, tienes que utilizar un TMySQL41Connection. Si se utiliza la misma versión de librería que de cliente probablemente con la 4.1 se podría conectar a un servidor MySQL 5.0, pero el requerimiento de correspondencia librería-conector a la misma versión es necesario.

   Aunque los detalles difieren entre las distintas base de datos, por lo general hay que establecer cuatro propiedades para conectarse a un servidor de base de datos:

• El nombre del servidor o su dirección IP.
• El nombre de la base de datos.
• El usuario.
• La contraseña.

   Cuando estas propiedades se establecen, se puede crear una conexión con el método, open. Si falla la conexión se lanza una excepción EDatabaseError. Utiliza la propiedad connected para comprobar si la conexión se ha establecido con el servidor de base de datos. Utiliza el método close para finalizar la conexión con el servidor.

Program ConectaDB
 
 var UnaConexion : TSQLConnection;
 
 Procedure CrearConexion;
 begin
   UnaConexion := TIBConnection.Create(nil);
   UnaConexion.Hostname := 'localhost';
   UnaConexion.DatabaseName := '/opt/firebird/examples/employee.fdb';
   UnaConexion.UserName := 'sysdba';
   UnaConexion.Password := 'contraseñamaestra';
 end;
 
 begin
   CrearConexion;
   UnaConexion.Open;
   if UnaConexion.Connected then
     writeln('¡Conexión realizada!')
   else
     writeln('¡Imposible!, porque si la conexión falla, '+
               'una excepción debe ser lanzada, por lo que este código no '+
                'será Ejecutado');
   UnaConexion.Close;
   UnaConexion.Free;
 end.

   Si se produce una excepción, lea atentamente el mensaje de error. Tal vez el servidor de base de datos no está funcionando, el nombre de usuario o la contraseña son incorrectos o el nombre o la dirección IP de base de datos estan escritos de forma incorrecta. Si el mensaje de error indica que la librería cliente no puede ser encontrada, comprueba si el cliente está instalado correctamente. A menudo, el mensaje de error muestra literalmente el nombre del archivo buscado. También es buena idea verificar en la documentación si alguna de estas propiedades está o no soportada para un conector concreto puesto que es posible que en algún caso deban dejarse sin rellenar (no me refiero a la documentación de la BBDD sino de la unidad que conecta).

¿Cómo ejecutar consultas directas o crear una tabla?

   SQLdb -el nombre lo dice todo- sólo funciona con servidores de base de datos que hacen uso de SQL. SQL significa Structured Query Language (Lenguaje estructurado de consulta). SQL es un lenguaje desarrollado para permitir trabajar con bases de datos relacionales. Prácticamente todos los sistemas de base de datos tiene su propio dialecto, pero un gran número de sentencias SQL son iguales en todos los sistemas de base de datos. Podemos hacer una diferencia entre las sentencias SQL que devuelven la información y sentencias que no devuelven información. Si desea utilizar la información que devuelve la sentencias SQL, tienes que utilizar el componente TSQLQuery (ver ¿Cómo leer datos de una tabla?). Si no piensas utilizar la información devuelta por la consulta SQL, entonces también puedes usar el método ExecuteDirect de un TSQLConnection.

   La mayoría de sistemas de base de datos ejecutan las sentencias SQL dentro de una transacción. Si desea que los cambios realizados dentro de una transacción estén disponible en otras transacciones, o disponer de los cambios disponible incluso después de cerrar la transacción, entonces tienes que realizar el commit de la transacción. Para soportar las operaciones SQLdb tiene el componente TSQLTransaction. Una sentencia SQL que se ejecuta por SQLdb siempre debe ser ejecutada dentro de una transacción. Incluso si el sistema de base de datos no soporta las transacciones. Además, hay sistemas de bases de datos que soportan transacciones para los que TSQLConnection no (todavía) soporta la transacción. Incluso entonces, debes utilizar el componente TSQLTransaction.

   Para utilizar TSQLConnection.ExecuteDirect para ejecutar una sentencia SQL debes especificar que Transaction se debe utilizar. A su vez, al utilizar TSQLTransaction debes especificar que TSQLConnection se debe utilizar.

   En el ejemplo siguiente se crea una tabla 'TBLNOMBRE' con los campos NOMBRE y nID e inserta dos registros. Las instrucciones SQL utilizadas no se explican. Para obtener más información acerca de las instrucciones SQL, su uso y su sintaxis, consulte la documentación del sistema de base de datos. El procedimiento CreateConnection se define en el ejemplo de código de ¿Cómo conectarse a un servidor de base de datos?.

program CreateTable;
 
 var AConnection : TSQLConnection;
     ATransaction : TSQLTransaction;
 
 procedure CreateTransaction;
 begin
   ATransaction := TSQLTransaction.Create;
   ATransaction.Database := AConnection;
 end;
 
 begin
   CreateConnection;
   CreateTransaction;
   AConnection.Transaction := ATransaction;
   AConnection.Open;
   ATransaction.StartTransaction;
   AConnection.ExecuteDirect('create table TBLNAMES (ID integer, NAME varchar(40));'); 
   
   // Some database-server types need a commit before you can use a newly created table. (Firebird)
   // With .Commit you also close the transaction
   ATransaction.Commit; 
 
   ATransaction.StartTransaction;
   AConnection.ExecuteDirect('insert into TBLNAMES (ID,NAME) values (1,'Name1');'); 
   AConnection.ExecuteDirect('insert into TBLNAMES (ID,NAME) values (2,'Name2');'); 
   ATransaction.Commit; 
   AConnection.Close;
   AConnection.Free;
   ATransaction.Free;
 end.

¿Cómo leer datos de una tabla?

   Utiliza el componente TSQLQuery para leer datos de una tabla. Un componente TSQLQuery debe estar enlazado a un componente TSQLConnection y a un componente TSQLTransaction para hacer su trabajo. El ajuste de TSQLConnection y de TSQLTransaction se discute en ¿Cómo conectarse a un servidor de base de datos? y en ¿Cómo ejecutar consultas directas o crear una tabla?.

   Cuando TSQLConnection, TSQLTransaction y TSQLQuery están conectados, entonces TSQLQuery necesita más ajustes. TSQLQuery tiene una propiedad SQL que contiene un objeto TStrings. La propiedad 'SQL' contiene la sentencia SQL que debe ejecutarse. Si todos los datos de una tabla debe ser leídos establece la propiedad SQL a SELECT * FROM nombretabla;. Utiliza open para leer la tabla desde el servidor y poner los datos en el conjunto de datos TSQLQuery. Los datos se pueden acceder a través de TSQLQuery hasta que la consulta se cierra con close.

   TSQLQuery es una subclase de TDataset. TDataset tiene una colección Fields que contiene todas las columnas de la tabla. El TDataset también mantiene una marca del registro actual. Utiliza First, Next, Prior y Last para cambiar el registro actual. Bof devuelve true (verdadero) si se llegó al primer registro, y Eof devuelve true si se llegó al último registro. Para leer el valor de un campo en el registro actual, en primer lugar hayamos el objeto TField adecuado y luego usar 'AsString', 'AsInteger', etc.

   A continuación se muestra un ejemplo que muestra todos los valores de la tabla como se hizo en ¿Cómo ejecutar consultas directas o crear una tabla?.

Program ShowData;
 
 var AConnection : TSQLConnection;
     ATransaction : TSQLTransaction;
 
 procedure GetQuery : TSQLQuery;
 var AQuery : TSQLQuery;
 begin
   AQuery := TSQLQuery.Create;
   AQuery.Database := FConnection;
   AQuery.Transaction := FTransaction;
   Result := AQuery;
 end;
 
 var Query : TSQLQuery;
 
 begin
   CreateConnection;
   CreateTransaction;
   Query := GetQuery;
   Query.SQL.Text := 'select * from tblNames';
   AConnection.Open;
   Query.Open;
   while not Query.Eof do
     begin
     Writeln('ID: ', Query.FieldByName('Name').AsInteger, 'Name: ' +
                                   Query.FieldByName('Name').AsString);
     Query.Next;
     end;
   Query.Close;
   AConnection.Close;
   Query.Free;
   ATransaction.Free;
   AConnection.Free;
 end.

   (El código anterior, por supuesto, no está terminado, se echa de menos bloques try ... finally. Sin embargo, el código anterior tiene la intención de mostrar el código para base de datos y por lo tanto los toques finales son dejados de lado.) Ten en cuenta que TSQLTransaction.StartTransaction no se utiliza. Esto no es necesario. Cuando TSQLQuery se abre, la instrucción SQL se ejecuta y si no hay ninguna transacción está disponible, esta se inicia automáticamente. El programador no necesita iniciar la transacción explícitamente. Lo mismo se aplica para la conexión gestionada por TSQLConnection. La conexión se abre según sea necesario, la línea Aconnection.Open no es realmente necesaria.

   Si se destruye un TSQLTransaction, un rollback (deshacer) automático será ejecutado. Los posibles cambios a los datos contenidos en la transacción se perderán.

¿Por qué TSQLQuery.RecordCount siempre devuelve 10?

   Para contar los registros de un dataset, usaremos RecordCount. Sin embargo, observa que RecordCount muestra el número de registros que se ha cargado desde el servidor. SQLdb no lee todos los registros al abrir un TSQLQuery de forma predeterminada, sólo los 10 primeros. Sólo cuando se accede al undécimo registro entonces el siguiente conjunto de 10 registros se carga. Usando .Last todos los registros se cargarán.

   Si desea conocer el número real de registros en el servidor hay que llamar primero '.Last' y luego llamar a .RecordCount. Hay una alternativa disponible. El número de registros devueltos por el servidor está determinado por el valor de la propiedad PacketRecords. El valor por defecto es 10, si se pone a -1 entonces todos los registros serán cargados a la vez.

Lazarus

   Lazarus tiene diversos componentes para mostrar datos de un TDataset en un formulario. En lugar de un bucle while y declaraciones Writeln usados en el ejemplo, puedes utilizar componentes para mostrar los datos de una tabla. Coloca los adecuados componentes TSQLConnection, TSQLTransaction y TSQLQuery en un formulario, a continuación, se conectan y configuran correctamente. Además se necesita un TDataSource, ajusta la propiedad TDatasource.Dataset al componente TSQLQuery utilizado. (Nota no establecer la propiedad TSQLQuery.Datasource al componente TDataSource. La propiedad TSQLQuery.Datasource se utiliza solamente en tablas maestro/detalle) A continuación puedes poner un TDBGrid en el formulario y establece la propiedad Datasource de la rejill (grid) al componente TDataSource agregado antes.

   Para ver si funciona todo, establece la propiedad Connected del TSQLConnection a True en el IDE de Lazarus. El IDE intenta conectar con el servidor de base de datos inmediatamente. Si funciona se puede establecer la propiedad TSQLQuery.Active a 'True'. Si todo está correcto, podrás ver -en el IDE- todos los datos de la tabla inmediatamente en la pantalla.

¿Cómo cambiar los datos en una tabla?

   Para cambiar datos en un registro, el TDataset (del que se deriva TSQLQuery) debe ponerse en modo de edición. Para activar el modo de edición podemos llamar a los métodos .Edit, . Inserto .Append. Utiliza el método .Edita para modificar el registro actual. Utiliza .Insert para crear un nuevo registro antes del registro actual. Utiliza .Append paara añadir un nuevo registro al final de la tabla. En modo edición puedes cambiar el valor de los campos a través de la propiedad Fields. Utiliza Post para validar los nuevos datos, si los datos son válidos entonces se abandona el modo de edición. Si se cambia a un nuevo registro -por ejemplo, utilizando .Next- y el conjunto de datos está en modo de edición, se llamará a .Post antes. Utiliza .Cancel para descartar todos los cambios realizados desde la última llamada a .Post y termina el modo de edición.

 Query.Edit;
 Consulta.FieldByName('NOMBRE').AsString := 'Nombre editado';
 Consulta.Post;

   Lo anterior no es la historia completa todavía. TSQLQuery se deriva de TBufDataset que hace uso de actualizaciones en un buffer. Actualización en buffer significa que después de llamado Post los cambios en el conjunto de datos son visibles de inmediato, pero no se envían al servidor de base de datos. Lo que sucede es que los cambios se mantienen en un registro de cambios. Cuando se llama al método .ApplyUpdates todos los cambios en el registro de cambios se envían al servidor de base de datos. Sólo entonces el servidor de base de datos conoce todos los cambios. Los cambios se envían al servidor en una transacción de TSQLTransaction. Asegúrese de establecer correctamente la transacción antes de ApplyUpdates. Después de aplicar las actualizaciones, se debe ejecutar commit para publicar o guardar los cambios.

   El siguiente es un ejemplo de la cambio de datos en una tabla, envío de los cambios al servidor y confirmación de la transacción.

 Program EditarDatos;
 
 var unaConexion : TSQLConnection;
     unaTransaccion : TSQLTransaction;
     Consulta : TSQLQuery;
 
 begin
   CrearConexion;
   CrearTransaccion;
   unaConexion.Transaction := unaTransaccion;
   Consulta := GetQuery;
   Consulta.SQL.Text := 'select * from tblNombres';
   Consulta.Open;
   Consulta.Edit;
   Consulta.FieldByName('NOMBRE').AsString := 'Nombre editado';
   Consulta.Post;
   Consulta.UpdateMode := upWhereAll;
   Consulta.ApplyUpdates;
   AConnection.Transaction.Commit;
   Consulta.Free;
   unaTransaccion.Free;
   unaConexion.Free;
 end.

   Para una discusión de UpdateMode sigue leyendo.

¿Cómo SQLdb envia los cambios al servidor de base de datos?

   En el ejemplo de código de ¿Cómo cambiar los datos en una tabla?, se encuentra la línea.

 Consulta.UpdateMode := upWhereAll;

sin ninguna explicación de lo que hace. La mejor manera de averiguar lo que esa línea hace es quitarla. Si se omite la orden y se sigue esta guía con precisión, se recibirá el siguiente mensaje de error:

 No update query specified and failed to generate one. (No fields for inclusion in where statement found)

   Para entender lo que salió mal, debes entender cómo los cambios se envían al servidor de base de datos. La única manera de obtener datos en un servidor SQL es mediante la ejecución de consultas SQL. SQL tiene tres tipos de consultas para tres maneras diferentes de manipular un registro. Para crear un nuevo registro, cambiar o eliminar un registro las sentencias insert, update y delete se ejecutan, respectivamente. Una sentencia de actualización (update) puede ser así:

 update TBLNAMES set NAME='Edited name' where ID=1;

   Para enviar un cambio al servidor de base de datos, SQLdb debe crear una consulta de actualización. Para crearla consulta, se necesitan tres cosas:

El nombre de la tabla

El nombre de la tabla se obtiene de analizar la consulta de selección, aunque esto no siempre funciona.

Una clásula UPDATE o INSERT

Estas contienen los campos que se deben cambiar.

Una clásula WHERE

Esta contiene los campos que determinan qué registros se deben cambiar.

   Todos los campos (cada TField en Fields) tiene una propiedad ProviderFlags. Sólo los campos con pfInUpdate en ProviderFlags se utilizarán en la clásula de actualización o inserción de la consulta. Por defecto todos los campos tienen pfInUpdate puesto en su propiedad ProviderFlags.

   Qué campos se utilizan en la clásula WHERE depende de la propiedad UpdateMode de la consulta y la propiedad ProviderFlags de los campos. Los campos con pfInkey en su ProviderFlags siempre se utilizan en la clásulaWHERE. Un campo tendrá el indicador pfInKey establecido de forma automática si el campo es parte de la clave principal de la tabla y TSQLQuery.UsePrimaryKeyAsKey devuelve True.

   El valor predeterminado para UpdateMode de la consulta es upWhereKeyOnly. En este modo se actualizan los campos sólo con pfInkey en su propiedad ProviderFlags 'se utilizan en la clásula WHERE. Si ninguno de los campos tienen el indicador pfInKey establecido, entonces no hay campos disponibles para la cláusula WHERE y el mensaje de error del principio de esta sección será devuelto. Puede resolver el problema así:

• Añadir una clave principal a la tabla y poner TSQLQuery.UsePrimaryKeyAsKey a 'True', o
• Poner el indicador pfInkey para uno o varios campos en el código.

   La propiedad UpdateMode puede tener dos posible valores más. UpWhereAll puede usarse para agregar todos los campos con el indicador pfInWhere establecido para la cláusula WHERE. Por defecto todos los campos tienen este indicador establecido. UpWhereChanged puede usarse para agregar sólo los campos que tienen el indicador pfInWhere establecido y que se han modificado del registro actual.

¿Cómo ejecutar una consulta mediante TSQLQuery?

   Junto a las declaraciones que devuelven un conjunto de datos (ver ¿Cómo leer datos de una tabla?) SQL tiene sentencias que no devuelven datos. Por ejemplo INSERT, UPDATE y DELETE no devuelven datos. Estas sentencias se pueden ejecutar mediante TSQLConnection.ExecuteDirect , pero TSQLQuery puede utilizarse también. Si no esperas devolver datos utiliza TSQLQuery.ExecSQL en lugar de TSQLQuery.Open. Utiliza TSQLQuery.Open para abrir el conjunto de datos devuelto por la consulta SQL.

   El siguiente procedimiento crea una tabla y se insertan dos registros utilizando TSQLQuery.

procedure CrearTabla;
  
  var Consulta : TSQLConsulta;
  
  begin
    Consulta := GetConsulta;
    Consulta.SQL.Text := 'create table TBLNOMBRES (ID integer, NOMBRE varchar(40));';
    Consulta.ExecSQL;
  
    Consulta.SQL.Text := 'insert into TBLNOMBRES (ID,NOMBRE) values (1,'Nombre1');';
    Consulta.ExecSQL;
  
    Consulta.SQL.Text := 'insert into TBLNOMBRES (ID,NOMBRE) values (2,'Nombre2');';
    Consulta.ExecSQL;
  
    Consulta.Close;
    Consulta.Free;
  end;

¿Cómo utilizar parámetros en una consulta?

   En el código de ejemplo de ¿Cómo ejecutar una consulta mediante TSQLQuery? la misma consulta se utiliza dos veces, sólo difieren en los valores que se insertan. Una manera mejor de hacerlo es mediante el uso de parámetros en la consulta.

   La sintaxis de los parámetros en las consultas es diferente en cada sistema de base de datos, pero las diferencias las maneja TSQLQuery. Coloca de nuevo los valores en la consulta con dos puntos precediendo al nombre del parámetro que desea utilizar. Por ejemplo:

 Consulta.SQL.Text := 'insert into TBLNOMBRES (ID,NOMBRE) values (:ID,:NOMBRE);';

   Esta consulta crea dos parámetros: 'ID' y 'NOMBRE'. Para determinar los parámetros, la consulta se analiza en el momento en que se asigna o modifica el texto de TSQLQuery.SQL. Todos los parámetros existentes se eliminarán y los nuevos parámetros se añadirán a la propiedad TSQLQuery.Params. Asignar un valor a un parámetro es similar a asignar un valor a un campo en el conjunto de datos:

 Query.Params.ParamByName('Nombre').AsString := 'Name1';

   No se puede saber desde consulta qué tipo de datos deben ser almacenados en el parámetro. El tipo de datos del parámetro se determina en el momento en que un valor se asigna al parámetro. Al asignar un valor utilizando . AsString, el parámetro se asigna al tipo de datos ftString. Puede determinar el tipo de datos directamente mediante el establecimiento de la propiedad DataType. Si un tipo de datos incorrecto se asigna al parámetro, entonces los problemas se producirán durante la apertura o ejecución de la consulta.

   En el ejemplo siguiente se crea la misma tabla del ejemplo anterior, pero ahora se utilizan parámetros:

 procedure CrearTablaUsandoParametros;
  
  var Consulta : TSQLQuery;
  
  begin
    Consulta := GetQuery;
    Consulta.SQL.Text := 'create table TBLNOMBRES (ID integer, NOMBRE varchar(40));';
    Consulta.ExecSQL;
  
    Consulta.SQL.Text := 'insert into TBLNOMBRES (ID,NOMBRE) values (:ID,:NOMBRE);';
  
    Consulta.Params.ParamByName('ID').AsInteger := 1;
    Consulta.Params.ParamByName('NOMBRE').AsString := 'Nombre1';
    Consulta.ExecSQL;
  
    Consulta.Params.ParamByName('ID').AsInteger := 2;
    Consulta.Params.ParamByName('NOMBRE').AsString := 'Nombre2';
    Consulta.ExecSQL;
  
    Consulta.Close;
    Consulta.Free;
  end;

   Observa que este ejemplo requiere más código que el ejemplo sin parámetros. Entonces, ¿qué es el ventaja de la utilización de parámetros? La velocidad es una de las razones. El ejemplo con parámetros es más rápido porque la consulta se analiza solamente una vez. TSQLQuery sólo analiza la consulta una vez, pero también el servidor de base de datos analiza la consulta una sola vez. La mayoría de los sistemas de base de datos soportan parámetros. Siempre que una consulta se utiliza más de una vez con diferentes valores para el parámetro cada vez, entonces el servidor de base de datos sólo analiza la consulta y los planes de la consulta una sola vez haciendo la ejecución considerablemente más rápida.

   Utiliza TSQLQuery.Prepare para determinar el momento en que se analiza y se planifica la consulta por el servidor de base de datos. Utiliza TSQLQuery.UnPrepare para asegurarse de que la consulta se analiza y se planifica cada vez por el servidor de datos.

   Otra razón para usar sentencias preparadas es la prevención de inyección de SQL, pero en algunos casos únicamente simplifica la codificación.

Solución de problemas:

Registro de sucesos de TSQLConnection

   Puedes hacer que TSQLConnection registre lo que está haciendo. Esto puede ser útil para ver exactamente lo que tu programa envía a la base de datos, para depurar los propios componentes de base de datos y también para optimizar las consultas.

   Nota: si utilizas comandos preparados o consultas parametrizadas (ver la sección anterior), los parámetros son a menudo enviados en binario por el descendiente de TSQLConnection (por ejemplo, TIBConnection), por lo que no se puedes simplemente copiar o pegar el código SQL registrado en una herramienta de consulta de la base de datos.

   En cualquier caso, el registro de la activad de la conexión puede dar una gran cantidad de información sobre lo que está haciendo tu programa.

   Otras alternativas son:

1. utilizar el depurador para recorrer el código base de datos si se ha construido el FPC o Lazarus con la depuración habilitada.
2. si utilizas controladores ODBC (al menos en Windows) puedes habilitar la salida tracelog en el panel de control de ODBC.
3. muchas bases de datos permiten controlar todas las ordennes que se le envían desde una determinada dirección IP o conexión.

   Para utilizar el registro de actividad de TSQLConnection, se requieren dos cosas:

1. indicar qué tipos de eventos del TSQLConnection deben registrarse
2. apuntar TSQLConnection a la función que recibe los eventos y los procesa (los registra en un archivo, que se imprima en la pantalla, etc)

   Esta función debe ser de tipo TDBLogNotifyEvent (ver sqldb.pp), por lo que seguirá este patrón:

 TDBLogNotifyEvent = Procedure (Sender : TSQLConnection; EventType : TDBEventType; Const Msg : String) of object;

   Este fragmento de código puede ilustrar esto:

 uses
 ...//
 TSQLConnection, //o un objeto heredero tal que TIBConnection, TMSSQLConnection
 ...//
 var
 type 
   TMyApplication = class(TCustomApplication); //esta es nuestra aplicación, la que utiliza la conexión
 ...//
   private
     // Este ejemplo guarda el registro en un stringlist:
     FConnectionLog: TStringList;
 ...//
   protected
     // Este procedimiento recibe los eventos que registra la conexión:
     procedure GetLogEvent(Sender: TSQLConnection; EventType: TDBEventType; Const Msg : String);
...
  procedure TMyApplication.GetLogEvent(Sender: TSQLConnection;
    EventType: TDBEventType; const Msg: String);
  // El procedimineto es llamado por TSQLConnection y guarda los mensajes recibidos
  // en la lista de cadenas FConnectionLog
  var
    Source: string;
  begin
    // Muy bien alineado a la derecha...
    case EventType of
      detCustom:   Source:='Custom:  ';
      detPrepare:  Source:='Prepare: ';
      detExecute:  Source:='Execute: ';
      detFetch:    Source:='Fetch:   ';
      detCommit:   Source:='Commit:  ';
      detRollBack: Source:='Rollback:';
      else Source:='Evento desconocido. Corrige el código del programa.';
    end;
    FConnectionLog.Add(Source + ' ' + Msg);
  end;

...
  // Necesitamos decirle a nuestro TSQLConnection lo que debe registrar:
    FConnection.LogEvents:=LogAllEvents; //= [detCustom, detPrepare, detExecute, detFetch, detCommit, detRollBack]
    // ... y el procedimiento de la conexión que debe enviar los eventos:
    FConnection.OnLog:=@Self.GetLogEvent;
...
  // Ahora podemos usar la conexión y la lista de cadenas FConnectionLog se llenará con los mensajes de registro.

   También podemos utilizar GlobalDBLogHook de TSQLConnection en lugar de registrar todo desde múltiples conexiones.

   Por último, la descripción anterior es la manera de hacer las cosas en FPC como se indica en la introducción, si se utiliza Lazarus, una forma más rápida es asignar un controlador de eventos al evento OnLog de TSQLConnection.

See also

* Trabajando con TSQLQuery.