Translations / i18n / localizations for programs/es

From Lazarus wiki
Jump to navigationJump to search

Deutsch (de) English (en) español (es) français (fr) 日本語 (ja) 한국어 (ko) polski (pl) português (pt) русский (ru) 中文(中国大陆)‎ (zh_CN)

Descripción general

   Cómo hacer que los programas utilicen diferentes cadenas para varios idiomas cómo inglés, chino, alemán, castellano, etc. Básicamente funciona de la siguiente forma: Añade un recurso de cadena (resourcestring) para cada literal, compila para obtener los archivos .rst y/o .po (el IDE lo hace automáticamente), crea un archivo .po para cada idioma (existen herramientas gráficas para ello) y utiliza las funciones de la unidad translations de la LCL para cargar el archivo adecuado al iniciar el programa.

Formatos de fechas, horas y números

   En Linux, BSD, Mac OS X hay diversas definiciones regionales/locales para definir el formato de la hora y de la fecha o del separador decimal. Para inicializar la RTL necesitas icluir la unidad clocale en la sección use de tu programa (archivo lpr).

Recursos de Cadena (Resourcestrings)

   Por ejemplo <delphi> resourcestring

   Etiqueta1 = 'Algo de texto';
   HolaMundo1 = 'Hola Mundo';</delphi>

   Son como constantes de cadena normales, lo que significa que se pueden asignar a cualquier cadena. Por ejemplo <delphi> Label1.Caption := HolaMundo1;</delphi>

   Al compilar se creará un archivo .rst por cada unidad, con el mismo nombre que esta, conteniendo los resursos de cadena (nombre y contenido)

Archivos .po

   Hay muchas herramientas gráficas libres (kbabel y poedit, por ejemplo) para editar archivos .po, que son texto simple al igual que los archivos .rst, pero con algunas opciones más, como una cabecera que proporciona los campos autor, la codificación, el idioma y fecha. Toda instalación de fpc proporciona la herramienta rstconv (windows: rstconv.exe). Esta herramienta se utiliza para convertir archivos .rst en archivos .po. El IDE realizar esta operación automáticamente.

   Ejemplo de uso de rstconv:

 rstconv -i unidad1.rst -o unidad1.po

Traduciendo

   Por cada idioma el archivo .po debe ser copiado y traducido. La unidad translation utiliza los códigos de idiomas habituales (en=inglés, de=alemán, es=español, it=italiano, ...) para buscarlos. Por ejemplo la traducción al alemán de unidad1.po se llamará unidad1.de.po. Por tanto hay que copiar el archivo unidad1.po en un archivo de nombre unidad1.it.po y así para todos los idiomas que queramos soportar y los traductores editaran el archivo .po específico de cada idioma.

   Nota para brasileños y portugueses: El IDE y la LCL de Lazarus únicamente tienen traducciones de portugués de Brasil y estos archivos se denominan con la extensión 'pb.po' y no 'pt.po'.

Opciones del IDE para la actualización automática de archivos .po

  • La unidad que contiene los recursos de cadena debe añadirse al paquete o proyecto.
  • Hay que proporcionar la ruta a .po si los archivos están en un directorio separado. Por ejemplo crear un directorio idiomas en el paquete/proyecto. Para proyectos ir a Proyecto > Opciones de proyecto, pestaña i18n. Para paquetes ir a Opciones > Integración en IDE.

   Cuando esta opción está activada, el IDE genera o actualiza el archivo .po base con la información contenida en los archivos .rst y .lrt (en cuyo caso la herramienta rstconv no será necesaria). El proceso de actualización se inicia mediante la recopilación de todas las entradas existentes en el .po base y en los archivos .rst y .lrt y luego aplica las siguientes características que encuentra y pone al día todo archivo .xx.po traducido.

Eliminación de entradas obsoletas

   Las entradas en el archivo .po base no se encontradas en el archivo en los archivos .rst y .lrt se eliminan, posteriormente, todas las entradas que se encuentran en archivos .xx.po traducidos que no se encuentran en el archivo .po base también se quitan. De esta manera los archivos .po se limpian de las entradas obsoletas y los traductores no tienen que traducir las entradas que no se utilizan.

Entradas duplicadas

   Las entradas duplicadas se producen cuando por alguna razón se utiliza el mismo texto para cadenas de recursos diferentes, un ejemplo, de esto es el archivo de Lazarus/ide/lazarusidestrconst.pas para la cadena 'Gutter';

<Delphi> dlfMouseSimpleGutterSect = 'Gutter';

dlgMouseOptNodeGutter = 'Gutter';
dlgGutter = 'Gutter';
dlgAddHiAttrGroupGutter   = 'Gutter';</Delphi>

   El archivo .rst de recursos para estas cadenas A converted .rst file for this resource strings tendría un aspecto similar a este en un archivo .po:

 #: lazarusidestrconsts.dlfmousesimpleguttersect
 msgid "Gutter"
 msgstr ""
 #: lazarusidestrconsts.dlgaddhiattrgroupgutter
 msgid "Gutter"
 msgstr ""
 etc.

   Donde las líneas que comienzan con "#:" se consideran como los comentarios y las herramientas empleadas para traducir estas entradas verán las repetidas líneas msgstr "Gutter" como entradas duplicadas y provocarán errores o advertencias al cargar o guardar. Las entradas duplicadas se consideran eventualmente normales en archivos .po y necesitan tener algo de contexto asociado. La palabra clave msgctxt se utiliza para agregar contexto a las entradas duplicadas y la herramienta de actualización automática de utiliza la entrada ID (el texto que sigue a "#:" ) como el contexto, para el ejemplo anterior se produciría algo así como esto:

 #: lazarusidestrconsts.dlfmousesimpleguttersect
 msgctxt "lazarusidestrconsts.dlfmousesimpleguttersect"
 msgid "Gutter"
 msgstr ""
 #: lazarusidestrconsts.dlgaddhiattrgroupgutter
 msgctxt "lazarusidestrconsts.dlgaddhiattrgroupgutter"
 msgid "Gutter"
 msgstr ""
 etc.

   En los archivos traducidos .xx.po la herramienta automática hace una comprobación adicional: si la entrada duplicada fue traducida ya, la nueva entrada toma la traducción previa, por lo que aparece como traducida automáticamente.

   La detección automática de duplicados aún no es perfecta, la detección se realiza cuando se agregan elementos a la lista y puede suceder que algunas entradas sin traducir se lean primero. Por lo tanto, puede llevar varias pasadas obtener todos los duplicados traducidos automáticamente por la herramienta.

Entradas confusas

   Los cambios en las cadenas de recursos afectan a las traducciones, por ejemplo cuando en un principio una cadena de recursos se define así: <Delphi> dlgEdColor = 'Syntax highlight';</Delphi>    esto produce una entrada en .po similar a esta

 #: lazarusidestrconsts.dlgedcolor
 msgid "Syntax higlight"
 msgstr ""

   que si se han traducido al idioma castellano (este ejemplo está tomado de la historia de lazarus), puede resultar en

 #: lazarusidestrconsts.dlgedcolor
 msgid "Syntax higlight"
 msgstr "Color"

   Supongamos ahora que, en un momento posterior, la cadena de recursos se ha cambiado a <Delphi> dlgEdColor = 'Colors';</Delphi>    la entrada en .po puede ser

 #: lazarusidestrconsts.dlgedcolor
 msgid "Colors"
 msgstr ""

   Tenga en cuenta que, si bien el ID sigue siendo igualmente lazarusidestrconsts.dlgedcolor la cadena ha cambiado de "Syntax highlight' a 'Colors', dado que la cadena se tradujo ya la traducción previa no puede coincidir con el nuevo significado. De hecho, para la nueva cadena probablemente 'Colores' puede ser una traducción mejor.    La herramienta de actualización automática avisa de esta situación y produce una entrada como esta:

 #: lazarusidestrconsts.dlgedcolor
 #, fuzzy
 #| msgid "Syntax highlight"
 msgctxt "lazarusidestrconsts.dlgedcolor"
 msgid "Colors"
 msgstr "Color"

   En los términos del formato de los archivos .po, el prefijo "#," significa que la entrada tiene una marca (confusa) y los programas traductores puede presentar al usuario un igu especial para este elemento, en este caso la marca significa que la traducción en su estado actual es dudosa y hay que revisarla con más cuidado por el traductor. El prefijo "#|" indica cuál fue la cadena anterior no traducida de esta entrada y le da al traductor una idea del porqué la entrada estaba marcada como confusa.

Traduciendo Formularios, Módulos de Datos y Marcos

   Cuando la opción i18n está activada para el proyecto/paquete el IDE crea automáticamente un archivo .lrt para cada formulario, cada vez que se guarda la unidad. Por tanto cuándo se habilita la opción por primera vez hay que abrir, modificar y guardar los formularios. Por ejemplo, si guardas un formulario unidad1 .pas el IDE crea el archivo unidad1.lrt. Y al compilar el IDE reúne todas las cadenas de todos los archivos .lrt y .rst en un único archivo .po, con el nombre del proyecto o del paquete, en el directorio i18n.

   Para los formularios que se traducen en tiempo de ejecución, hay que asignar un valor que apunte al achivo de traducción a LRSTranslator (definido en LResources) en la sección de inicio de una de las unidades del proyecto. <Delphi> ...

uses
  ...
  LResources;
...
...
initialization
  LRSTranslator:=TPoTranslator.Create('/ruta/al/archivo/po'); </Delphi>

   La clase que traduce utilizando archivos .po, TPoTranslator, no está disponible en la LCL. Esta es una posible implementación (tomada en parte de DefaultTranslator.pas de la LCL) El código siguiente ya no se necesita si utilizas Lazarus 0.9.29. Sólo tienes que incluir DefaultTranslator en la cláusula uses:

<Delphi> unit PoTranslator;

{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, typinfo, Translations;
type

 { TPoTranslator }
 TPoTranslator=class(TAbstractTranslator)
 private
    FPOFile:TPOFile;
 public
   constructor Create(POFileName:string);
   destructor Destroy;override;
   procedure TranslateStringProperty(Sender:TObject; 
   const Instance: TPersistent; PropInfo: PPropInfo; var Content:string);override;
end;
implementation
{ TPoTranslator }
constructor TPoTranslator.Create(POFileName: string);
begin
  inherited Create;
  FPOFile:=TPOFile.Create(POFileName);
end;
destructor TPoTranslator.Destroy;
begin
  FPOFile.Free;
  inherited Destroy;
end;
procedure TPoTranslator.TranslateStringProperty(Sender: TObject;
 const Instance: TPersistent; PropInfo: PPropInfo; var Content: string);
var
  s: String;
begin
  if not Assigned(FPOFile) then exit;
  if not Assigned(PropInfo) then exit;
{DO we really need this?}
  if Instance is TComponent then
   if csDesigning in (Instance as TComponent).ComponentState then exit;
{End DO :)}
  if (AnsiUpperCase(PropInfo^.PropType^.Name)<>'TTRANSLATESTRING') then exit;
  s:=FPOFile.Translate(Content, Content);
  if s<> then Content:=s;
end;
end. </Delphi>

   Alternativamente se puede transformar el archivo .po en una .mo, utilizando msgfmt, y utilizar la unidad DefaultTranslator. <Delphi> ...

uses
...
DefaultTranslator;</Delphi>

   con ello se buscará automáticamente en varios lugares preestablecidos un archivo .mo; la desventaja es que hay que mantener ambos, los archivos .mo para la unidad DefaultTranslator y los archivos .po para TranslateUnitResourceStrings.

   Si utilizamos DefaultTranslator, se intentará detectar automáticamente la lengua basandose en la variable de entorno LANG (modificable utilizando la opción --lang de la línea de órdenes), buscando entonces en esos lugares la traducción (LANG representa la lengua deseada):

  • <Application Directory>/LANG/<Application Filename>.mo
  • <Application Directory>/languages/LANG/<Application Filename>.mo
  • <Application Directory>/locale/LANG/<Application Filename>.mo
  • <Application Directory>/locale/LC_MESSAGES/LANG/<Application Filename>.mo

   en sistemas *NIX esto se verá así

* /usr/share/locale/LANG/LC_MESSAGES/<Application Filename>.mo

   también usará la parte corta del idioma (e.g. si es " es_ES" o " es_ES.UTF-8" y este no existe también probará con "es")

Seleccionando el idioma en el arranque el programa

   Para cada fichero .po hay que hacer una llamada a la función TranslateUnitResourceStrings de la unidad de translations de la LCL. Por ejemplo:

<delphi> {lo pimero: añadir las unidades "gettext" y "translations" en la cláusula uses}

procedure TForm1.FormCreate(Sender: TObject);
 var
   PODirectorio, Idioma, IdiomaDevuelto: String;
 begin
   PODirectorio := '/ruta/a/lazarus/lcl/languages/';
   GetLanguageIDs(Idioma, IdiomaDevuelto); // en la unidad "gettext"
   TranslateUnitResourceStrings('LCLStrConsts', PODirectorio + 'lclstrconsts.%s.po', Idioma, IdiomaDevuelto);
   MessageDlg('Título', 'Texto', mtInformation, [mbOk, mbCancel, mbYes], 0);
end;</delphi>

Compilando los archivos .po dentro del ejecutable

   Si no deseas instalar los archivos .po, sino poner todos los archivos de la aplicación en el ejecutable, utiliza lo siguiente:

  • Crea una nueva unidad (¡no un formulario!).
  • Convierte los archivos .po en .lrs utilizando la utilidad lazres del directorio tools:
 ./lazres unidad1.lrs unidad1.es.po

   Esto creará un archivo de inclusión unit1.lrs que empieza así <delphi> LazarusResources.Add('unidad1.es','PO',[...</delphi>

  • Añade este código:

<delphi> uses LResources, Translations;

resourcestring
  MyCaption = 'Caption';
function TranslateUnitResourceStrings: boolean;
var
  r: TLResource;
  POFile: TPOFile;
begin
  r:=LazarusResources.Find('unidad1.es','PO');
  POFile:=TPOFile.Create;
  try
    POFile.ReadPOText(r.Value);
    Result:=Translations.TranslateUnitResourceStrings('unidad1',POFile);
  finally
    POFile.Free;
  end;
end;
initialization
  {$I unidad1.lrs}</delphi>
  • Llama a TranslateUnitResourceStrings al comienzo del programa. Puedes hacerlo en la sección de inicialización si quieres.

Traducciendo el IDE

Archivos

   Los archivos .po del IDE están en el directorio de fuentes de Lazarus:

  • lazarus/languages cadenas para el IDE
  • lcl/languages/ cadenas para la LCL
  • ideintf/languages/ cadenas para el interfaz del IDE

Traductoress

  • La traducción al alemán está a cargo de Joerg Braun.
  • La traducción al finés está a cargo de Seppo Suurtarla
  • La traducción al ruso está a cargo de Maxim Ganetsky

   Si deseas iniciar una nueva traducción, pregunta en el correo si alguien ya está trabajando en ello.

   Por favor, lee atentamente: Traducciones

Trabajos previstos / ToDos

IDE Development: Translations, i18n, lrt, po files