mysql/pl

│ English (en) │ español (es) │ français (fr) │ polski (pl) │

Portal bazy danych

Bibliografia: Informacje ogólne Biblioteki Typy pól Kontrolki FAQ SQL-instrukcje Praca z TSQLQuery Aplikacje bazodanowe w pamięci Poradniki/porady praktyczne: Przegląd 0 - Konfiguracja bazy danych 1 - Rozpoczęcie pracy 2 - Edycja 3 - Zapytania 4 - Moduły danych Informacje o programowaniu Bazy danych Advantage - MySQL - MS SQL - Postgres - Interbase - Firebird - Oracle - ODBC - Paradox - SQLite - dBASE - MS Access - Zeos

Przegląd

Możesz użyć Free Pascal/Lazarus, aby uzyskać dostęp do serwera bazy danych MySQL.

Win64: zobacz ostrzeżenie tutaj dotyczące nieużywania niektórych wersji FPC/Lazarus Win64.

Zalety MySQL:

• Jest bardzo szeroko stosowany i dostępny
• Chociaż starsze wersje miały zasłużoną opinię, że nie są prawdziwymi RDBMS, nowsze wersje obsługują właściwości ACID, jeśli są prawidłowo skonfigurowane (z odpowiednim zapleczem pamięci)

Wady MySQL:

• Opiekunowie MySQL łamią binarną kompatybilność między wersjami bibliotek klienta. Oznacza to, że dla każdej nowej wersji trzeba wykonać tłumaczenie FPC/Lazarus, co spowalnia działanie.
• Licencja może być ograniczona dla niektórych użytkowników (np. We wdrożeniach komercyjnych). Istnieją kompatybilne, prawdopodobnie mniej restrykcyjne alternatywy, takie jak MariaDB.

Z tego powodu wielu użytkowników Lazarusa/FPC preferuje bazy danych Firebird lub PostgreSQL.

Licencjonowanie MySQL

Przed znaczącym wdrożeniem MySQL nie zapomnij przeczytać jej licencji.

SQLDB

Lazarus 1.2 (z FPC 2.6.2), obsługuje

• Biblioteka klienta MySQL 4.0
• Biblioteka klienta MySQL 4.1
• Biblioteka klienta MySQL 5.0
• Biblioteka klienta MySQL 5.1
• Biblioteka klienta MySQL 5.5 (obsługiwana od wersji Lazarus 1.0.8)
• Biblioteka klienta MySQL 5.6 (obsługiwana od Lazarusa ?)

Nowsze wersje FPC/Lazarus mogą obsługiwać nowsze biblioteki klienta MySQL.

Upewnij się, że używasz odpowiedniego komponentu połączenia dla swojej wersji biblioteki klienta. Więc jeśli masz zainstalowane biblioteki klienta dla MySQL 4.1, musisz użyć komponentu TMySQL41Connection, nawet jeśli serwer działa w wersji 4.0 lub 5.0. Powodem tego jest to, że biblioteki klienckie MySQL często łamią kompatybilność ich API, więc każda wersja wymaga innego sterownika Pascala.

W systemach typu *nix kod SQLDB może szukać zwykłej wersji biblioteki bez sufiksów numerów wersji. Możesz sobie z tym poradzić na kilka sposobów:

• (w wielu Linuksach) zainstalowanie biblioteki w wersji -dev
• utworzenie dowiązania symbolicznego twojej konkretnej nazwy biblioteki do tej, której szuka FPC (raczej hakerskie)
• użycie TSQLDBLibraryLoader, aby określić nazwę biblioteki przed załadowaniem połączenia

Samouczki SQLDB i przykładowy kod

BigChimp wrzesień 2012: uwaga: wiele z tych samouczków to zduplikowany kod i można je skonsolidować. Proponuję przenieść jak najwięcej do samouczka SQLDB zorientowanego na GUI i utworzyć osobną stronę samouczka bazy danych FPC, aby utworzyć przykład trybu tekstowego

Uruchom serwer MySQL działający w systemie Linux lub Windows

Postępuj zgodnie z instrukcjami zawartymi w podręczniku użytkownika MySQL. Upewnij się, że demon mysqld działa niezawodnie i że wszyscy potencjalni użytkownicy (w tym root, mysql, Ty i wszyscy inni, którzy mogą tego potrzebować) mają tyle uprawnień, ile potrzebują, z tylu hostów, ile potrzeba (takich jak 'localhost', nazwa hosta lokalnego i inne hosty w twojej sieci), o ile jest to zgodne z bezpieczeństwem. Zaleca się, aby wszyscy użytkownicy, w tym root, mieli hasła. Przetestuj działanie systemu bazy danych, korzystając z przykładów podanych w instrukcji i sprawdź, czy wszyscy użytkownicy naprawdę mają niezawodny dostęp.

Spraw, aby MySQL działał dla FPC w trybie tekstowym

W katalogu $(fpcsrcdir)/packages/base/mysql/ znajduje się przykładowy program. Możesz znaleźć katalog ze źródłami fpc w Lazarusie: Narzędzia -> Opcje -> Pliki -> Katalog źródłowy FPC (en: Tools -> Options -> Files -> FPC source directory). Możliwe ścieżki do katalogu mysql to /usr/share/fpcsrc/packages/base/mysql/ (rpm install) lub C:\lazarus\fpcsrc\packages\base\mysql\ (windows). Ten katalog zawiera również moduły mysql.pp, mysql_com.pp i mysql_version.pp. Przed uruchomieniem skryptu testowego musisz utworzyć bazę danych o nazwie testdb: zrób to, logując się do monitora mysql (jako root z pełnymi uprawnieniami) i wydając następującą instrukcję SQL:

CREATE DATABASE testdb;

następnie upewnij się, że wszyscy właściwi użytkownicy mają do niego odpowiednie uprawnienia dostępu

GRANT ALL ON testdb TO johnny-user IDENTIFIED BY 'johnnyspassword';

Istnieje skrypt o nazwie mkdb, który powinieneś teraz spróbować uruchomić:

sh ./mkdb

Prawdopodobnie zakończy się to niepowodzeniem, ponieważ system nie pozwoli anonimowemu użytkownikowi uzyskać dostęp do bazy danych. Zmień więc skrypt za pomocą edytora tak, aby wiersz wywołujący mysql brzmiał:

mysql -u root -p  ${1-testdb} << EOF >/dev/null

i spróbuj uruchomić go ponownie, wprowadzając hasło po wyświetleniu monitu. Przy odrobinie szczęścia mogłeś stworzyć testową bazę danych: przetestuj ją (będąc zalogowanym do monitora mysql), wydając instrukcję mysql

select * from FPdev;

Powinieneś zobaczyć tabelę zawierającą ID, nazwę użytkownika i adres e-mail niektórych programistów FPC.

Teraz spróbuj uruchomić program testowy testdb.pp (może to wymagać skompilowania i prawie na pewno zakończy się niepowodzeniem przy pierwszej próbie !!).

Zauważyłem, że program nie mógł połączyć się z mysql z kilku powodów:

• Mój system (SuSE Linux v9.0) instaluje mysql v4.0.15, a nie wersję 3, dla której pakiet został zaprojektowany.

• Program musi mieć nazwy użytkowników i hasła, aby uzyskać dostęp do bazy danych.

• Kompilator musi wiedzieć, gdzie znaleźć biblioteki mysql (JEŚLI NIE ZAINSTALOWAŁEŚ BIBLIOTEK PROGRAMISTYCZNYCH MYSQL, ZRÓB TO TERAZ!)

Utworzyłem kopię pliku testdb.pp o nazwie trydb.pp, zamiast edytować oryginał - oznacza to, że oryginalne pliki nadal są naprawiane w kolejnych aktualizacjach CVS. Skopiowałem również pliki znalezione w podkatalogu mysql/ver40/ do głównego podkatalogu mysql/, zmieniając ich nazwy na mysql_v4.pp, mysql_com_v4.pp i mysql_version_v4.pp, pamiętając o zmianie nazwy modułóww każdym pliku. Zmieniłem instrukcję użycia w trydb.pp na

uses mysql_v4

i oświadczenie w mysql_v4.pp do

uses mysql_com_v4

Dodałem wiersz do /etc/fpc.cfg, aby wskazać moje biblioteki:

-Fl/lib;/usr/lib

Następujący krok może nie być konieczny, jeśli biblioteki deweloperskie są zainstalowane, ponieważ łącza zostaną utworzone za Ciebie, ale sprawdzenie nigdy nie zaszkodzi. Musiałem znaleźć prawdziwą nazwę biblioteki mysqlclint w katalogu /usr/lib i w moim przypadku musiałem wydać polecenie powłoki:

ln -s libmysqlclient.so.12.0.0 lmysqlclient

aby utworzyć dowiązanie symboliczne umożliwiające FPC znalezienie biblioteki. Na wszelki wypadek stworzyłem też link

ln -s libmysqlclient.so.12.0.0 mysqlclient

i umieściłem podobne linki w różnych innych katalogach: nie jest to absolutnie konieczne, ale na wszelki wypadek ...! Niektórzy użytkownicy mogą potrzebować dodać następujące łącze:

ln -s libmysqlclient.so.12.0.0 libmysqlclient.so

Zmodyfikowałem trydb.pp, aby zawierał dane użytkownika, początkowo dodając hosta, użytkownika i hasło jako stałe Pchar:

const
  host : Pchar= 'localhost';
  user : Pchar= 'myusername';
  passwd: Pchar = 'mypassword';

Template:Uwaga Odkryłem również, że nie mogę połączyć się z mysql za pomocą wywołania mysql_connect(), ale musiałem użyć mysql_real_connect(), który ma o wiele więcej parametrów. Aby jeszcze bardziej skomplikować sprawę, wydaje się, że liczba parametrów zmieniła się między wersją 3 (w której jest siedem) a wersją 4 (w której jest osiem). Przed użyciem mysql_real_connect musiałem użyć mysql_init(), którego nie ma w oryginalnym mysql.pp, ale znajduje się w mysql_v4.pp.

Tak więc kod do połączenia z bazą danych to teraz:

{ kilka dodatkowych zmiennych }
var
  alloc : PMYSQL;
  
{fragment głównego programu}
  
begin
  if paramcount=1 then
  begin
    Dummy:=Paramstr(1)+#0;
    DataBase:=@Dummy[1];
  end;
  
  Writeln('Przydzielanie miejsca ...');
  alloc := mysql_init(PMYSQL(@qmysql));
  Write('Łączę się z MySQL ...');
  sock := mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
  if sock=Nil then
  begin
    Writeln(stderr,'Nie można połączyć się z MySQL');
    Writeln(stderr, 'Błąd: ', mysql_error(@qmysql));
    halt(1);
  end;
  Writeln('Gotowe.');
  Writeln('Parametry połączenia:');
 {$ifdef Unix}
  writeln('Mysql_port      : ',mysql_port);
  writeln('Mysql_unix_port : ',mysql_unix_port);
 {$endif}
  writeln('Host info       : ',mysql_get_host_info(sock));
  writeln('Server info     : ',mysql_stat(sock));
  writeln('Client info     : ',mysql_get_client_info);
  
  Writeln('Wybór bazy danych ',DataBase,'...');
  if mysql_select_db(sock, DataBase) < 0 then
  begin
    Writeln(stderr,'Nie udało się wybrać bazy danych ',Database);
    Writeln(stderr,mysql_error(sock));
    halt(1);
  end;
 {... dalej oryginalna zawartość pliku testdb.pp}

Teraz - gotowy do rozpoczęcia kompilacji trydb.pp?

 fpc trydb

sukces! Teraz uruchom to:

 ./trydb

Super! Mam listę twórców FPC!

Kilka dodatkowych ulepszeń: uczyń wprowadzanie danych użytkownika i poleceń mysql interaktywnymi, używając zmiennych zamiast stałych, i pozwól na wprowadzenie kilku poleceń SQL, dopóki nie wydamy polecenia quit: zobacz pełna lista programów, gdzie dane użytkownika są wprowadzane z konsoli, a program przechodzi w pętlę, w której z konsoli wprowadza się polecenia SQL (bez średnika terminala) i wypisuje odpowiedzi, aż do wpisania „quit” z klawiatury.

Zobacz przykładową lista konsoli.

Łączenie się z MySQL z aplikacji Lazarus

Ten poradnik pokazuje, jak podłączyć Lazarus do bazy danych MySQL i wykonywać proste zapytania, używając tylko podstawowych komponentów Lazarusa; nie używa żadnych komponentów Data Aware, ale ilustruje zasady współpracy z bazą danych.

Utwórz nowy projekt w Lazarusie:

Projekt -> Nowy projekt -> Aplikacja (en: Project -> New Project -> Application)

Pojawi się nowy automatycznie wygenerowany formularz.

Powiększ formularz, aby wypełnić mniej więcej połowę ekranu, a następnie zmień nazwę formularza i jego podpis na „TryMySQL”.

Z zakładki komponentów Standard umieść trzy pola edycji w lewym górnym rogu formularza i bezpośrednio nad każdym z nich umieść etykietę. Zmień im odpowiednio właściwość Caption na „Serwer” lub „Host” (a Name na HostLLabel, HostEdit), „Użytkownik” (i UserLabel, UserEdit) oraz „Hasło” (z PasswdLabel i PasswdEdit). Alternatywnie możesz użyć komponentów LabelledEdit z zakładki Additional.

Zaznacz pole Passwd Edit i znajdź właściwość PasswordChar: zmień to na * lub inny znak, aby po wpisaniu hasła znaki nie pojawiały się na ekranie, ale były powtarzane serią znków *. Upewnij się, że właściwość Text każdego pola edycji jest pusta.

Teraz umieść kolejne pole edycji i etykietę u góry po prawej stronie formularza. Zmień etykietę na „Wpisz polecenie SQL” i nazwij ją CommandEdit.

Umieść trzy przyciski na formularzu: dwa po lewej stronie pod polami edycji i jeden po prawej stronie pod polem poleceń.

Oznacz przyciski po lewej stronie „Połącz z bazą” (ConnectButton) i „Wyjdź” (ExitButton), a przycisk po prawej stronie „Wyślij zapytanie” (QueryButton).

Umieść duże okno memo z etykietą i nazwą ją „Wyniki” (ResultMemo) w prawym dolnym rogu, aby wypełnić większość dostępnego miejsca. Znajdź właściwość ScrollBars i wybierz ssAutoBoth, aby paski przewijania pojawiały się automatycznie, jeśli tekst wypełni przestrzeń. Ustaw właściwość WordWrap na True.

Umieść pasek stanu Status Bar(z zakładki Common Controls) na dole formularza i ustaw jego właściwość SimpleText na „TryMySQL”.

Zrzut ekranu formularza można zobaczyć tutaj: Mysql Przykładowy zrzut ekranu

Teraz musimy napisać kilka procedur obsługi zdarzeń.

Trzy pola edycji po lewej stronie służą do wprowadzania nazwy hosta (adresu serwera), nazwy użytkownika i hasła. Gdy zostaną one wprowadzone pomyślnie, kliknij przycisk Połącz. Procedura obsługi zdarzeń OnCLick dla tego przycisku jest oparta częściowo na powyższym programie FPC w trybie tekstowym.

Odpowiedzi z bazy danych należy zamienić na ciągi znaków i wyświetlić w polu Memo. Instrukcje tryby tekstowego Pascala write i writeln, mogą wykonywać wiele konwersji 'w locie', ale użycie pola Memo do wyjścia tekstowego wymaga jawnej konwersji typów danych na poprawny ciąg: dlatego zmienne Pchar muszą zostać przekonwertowane na ciągi typu String przy użyciu funkcji StrPas, a liczby całkowite muszą być konwertowane za pomocą IntToStr.

Ciągi znaków są wyświetlane w polu Memo przy użyciu:

procedure ShowString(S : string);
(* wyświetl ciąg w polu Memo *)
begin
  trymysqlForm1.ResultsMemo.Lines.Add(S)
end;

Procedura obsługi zdarzeń ConnectButton wygląda następująco:

procedure TtrymysqlForm1.ConnectButtonClick(Sender: TObject);
(* Połącz się z MySQL przy użyciu danych użytkownika z pól tekstowych głównego formularza *)
var strg: string;
  
begin
  dummy1 :=  trymysqlForm1.HostEdit.text+#0;
  host := @dummy1[1];
  dummy2 := trymysqlForm1.UserEdit.text+#0;
  user := @dummy2[1] ;
  dummy3 := trymysqlForm1.PasswdEdit.text+#0;
  passwd := @dummy3[1] ;

  alloc := mysql_init(PMYSQL(@qmysql));
  sock :=  mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
  if sock=Nil then
    begin
      strg :='Nie można połączyć się z MySQL.'; showstring (strg);
      Strg :='Błąd: '+ StrPas(mysql_error(@qmysql)); showstring (strg);
    end
    else
    begin
      trymysqlForm1.statusBar1.simpletext := 'Połączono z MySQL';
      strg := 'Teraz wybieram bazę danych: ' + database; showstring (strg);
 {$ifdef Unix}
      strg :='Mysql_port      : '+ IntToStr(mysql_port); showstring (strg);
      strg :='Mysql_unix_port : ' + StrPas(mysql_unix_port); showstring (strg);
 {$endif}
      Strg :='Host info       : ' + StrPas(mysql_get_host_info(sock));
      showstring (strg);
      Strg :='Server info     : ' + StrPas(mysql_stat(sock)); showstring (strg);
      Strg :='Client info     : ' + Strpas(mysql_get_client_info);  showstring (strg);
  
      trymysqlForm1.statusbar1.simpletext := 'Wybór bazy danych ' + DataBase +'...';
      if mysql_select_db(sock,DataBase) < 0 then
      begin
        strg :='Nie udało się wybrać bazy danych '+ Database; ShowString (strg);
        Strg := mysql_error(sock); ShowString (strg);
      end
    end;
end;

Pole tekstowe po prawej stronie umożliwia wprowadzenie instrukcji SQL bez średnika terminala; gdy jesteś zadowolony z jego zawartości lub składni, naciśnij przycisk SendQuery, zapytanie zostanie przetworzone, a wyniki zostaną zapisane w polu ResultsMemo.

Procedura obsługi zdarzeń SendQuery jest ponownie oparta na wersji trybu tekstowego FPC, z tą różnicą, że ponownie należy wykonać jawną konwersję typu, zanim ciągi zostaną wyświetlone w polu Memo.

Różnica w stosunku do programu FPC działającego w trybie tekstowym polega na tym, że w przypadku wykrycia błędu program nie zatrzymuje się, a MySQL nie jest zamykany; zamiast tego sterowanie wraca do głównego formularza i daje możliwość poprawienia wpisu przed ponownym wysłaniem polecenia. Aplikacja zostaje ostatecznie zamknięta (z zamknięciem MySQL) po kliknięciu przycisku 'Zakończ'.

Kod dla SendQuery jest następujący:

procedure TtrymysqlForm1.QueryButtonClick(Sender: TObject);
var
  dumquery, strg: string;
begin
  dumquery := TrymysqlForm1.CommandEdit.text;
  dumquery := dumquery+#0;
  query := @dumquery[1];
  trymysqlForm1.statusbar1.simpletext := 'Wykonywanie zapytania: '+ dumQuery +'...';
  strg := 'Wykonywanie zapytania: ' + dumQuery; showstring (strg);
  if (mysql_query(sock,Query) < 0) then
  begin
    Strg :='Zapytanie nie powiodło się '+ StrPas(mysql_error(sock)); showstring (strg);
  end
  else
  begin
    recbuf := mysql_store_result(sock);
    if RecBuf=Nil then
    begin
      Strg :='Zapytanie zwróciło wynik nil.'; showstring (strg);
    end
    else
    begin
      strg :='Liczba zwróconych rekordów: ' + IntToStr(mysql_num_rows (recbuf));
      Showstring (strg);
      Strg :='Liczba pól w rekordzie: ' + IntToStr(mysql_num_fields(recbuf));
      showstring (strg);
      rowbuf := mysql_fetch_row(recbuf);
      while (rowbuf <>nil) do
      begin
        Strg :='(Id: '+ rowbuf[0]+', Imię: ' + rowbuf[1]+ ', Email : ' +
        rowbuf[2] +')';
        showstring(strg);
        rowbuf := mysql_fetch_row(recbuf);
      end;
    end;
  end;
end;

Zapisz swój projekt i naciśnij Uruchom -> Uruchom (en: Run -> Run)

Pobierz przykładowy kod źródłowy

Template:Uwaga Pełny listing programu jest dostępny tutaj / pobierz przykładowy kod źródłowy

Lazarus, MySQL i UTF-8

Poniższe może być wymagane również w przypadku innych stron kodowych/zestawów znaków

UTF-8 Unicode to wygodne wielobajtowe kodowanie zestawu znaków, które umożliwia pracę z tekstami wielojęzycznymi bez konieczności stosowania WideStrings. Obsługiwany jest zarówno przez komponenty Lazarus SQLdb, jak i MySQL od wersji 4.1 poprzez wybór odpowiedniego zestawu znaków.

Jednak ustawiając to kodowanie tak po prostu jako domyślne dla

• twojej tabeli i
• komponentu połączenia MySQL (np. TMySQL51Connection.CharSet:='UTF8';)

spowoduje nieprawidłowe przechowywanie i pobieranie ciągów znaków UTF-8: każdy znak akcentowany/międzynarodowy zostanie wyświetlony jako znak zapytania (?). Najwyraźniej powodem tego jest to, że biblioteka klienta MySQL jest kompilowana tak, aby domyślnie oczekiwała zestawu znaków Latin1.

Aby umożliwić poprawną komunikację między Lazarusem i biblioteką klienta MySQL a serwerem MySQL, należy wykonać dodatkowe dwa zapytania za każdym razem gdy nawiązywane jest połączenie z bazą danych:

SET CHARACTER SET `utf8`

i

SET NAMES 'utf8'

Pierwsze zapytanie zapewni, że aplikacja otrzyma ciągi znaków z poprawnym kodowaniem, a drugie powie MySQL, aby nie konwertował ciągów, które otrzymuje z aplikacji.

Proste demo MySQL przy użyciu komponentu TMySQL5xConnection

Oto kod, który działa jako szybkie demo, aby łatwo było go utworzyć i uruchomić. Podobnie jak w przypadku wszystkich komponentów SQLDB, upewnij się, że biblioteka klienta bazy danych znajduje się we właściwym miejscu:

• w systemie Windows: biblioteka DLL, np. libmysql.dll jest umieszczany w katalogu wyjściowym projektu (w którym jest generowany plik wykonywalny). Alternatywnie możesz również umieścić go w katalogu Windows/system32
• w systemie Linux/OSX: zainstaluj bibliotekę klienta mysql w swojej ścieżce (np. używając menedżera pakietów Twojej dystrybucji)

Podczas dystrybucji aplikacji upewnij się, że na komputerze użytkownika znajduje się odpowiednia biblioteka klienta MySQL. Ponieważ może to stanowić problem, być może użycie innego silnika bazy danych może mieć większy sens.

Przykład kodu

Poniższy przykład używa kodu do wypełnienia kontrolek danymi. Możesz także użyć kontrolek powiązanych z danymi, co może być szybsze/łatwiejsze. Zobacz przykład poniżej lub SQLdb Samouczek1.

Umieść w formularzu trzy pola edycji, pole notatki i kilka przycisków. Musisz dodać mysqlXXconn i sqldb do instrukcji uses.

W tym przykładzie DBMS MySQL ma użytkownika „root” bez hasła i bazę danych „test1” z tabelą „tPerson”, która ma trzy pola: „personid” (int), „sername” (varchar(40)) i „dob” (data i godzina). Wprowadzono również niektóre dane testowe.

Najpierw należy kliknąć przycisk btnTest, ponieważ tworzy on połączenie z systemem DBMS. Zwróć uwagę na linię, która stosuje aktualizacje - bez tego zmienione lub nowe dane nie zostaną zapisane z powrotem do DB, chociaż będą w pamięci i można je wyświetlić za pomocą btnFirst i btnNext.

Przykładowy kod

Poniższy przykład używa kodu do wypełnienia kontrolek danymi. Możesz także użyć kontrolek powiązanych z danymi, co może być szybsze/łatwiejsze. Zobacz przykład poniżej lub SQLdb_Tutorial1.

Umieść w formularzu trzy pola edycji, pole notatki i kilka przycisków. Musisz dodać mysqlXXconn i sqldb do instrukcji uses.

W tym przykładzie DBMS MySQL ma użytkownika „root” bez hasła i bazę danych „test1” z tabelą „tPerson”, która ma trzy pola: „personid” (int), „sername” (varchar (40)) i „dob” (data i godzina). Wprowadzono również niektóre dane testowe.

Najpierw należy kliknąć przycisk btnTest, ponieważ tworzy on połączenie z systemem DBMS. Zwróć uwagę na linię, która stosuje aktualizacje - bez tego zmienione lub nowe dane nie zostaną zapisane z powrotem w DB, chociaż będą w pamięci i można je wyświetlić za pomocą btnFirst i btnNext.

unit unt_db;
// Przykład oparty na:
// http://www.lazarus.freepascal.org/index.php?name=PNphpBB2&file=viewtopic&t=5761
// od tpglemur na tym forum
{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  mysql50conn, sqldb, StdCtrls;
type
  { TForm1 }
  TForm1 = class(TForm)
    btnTest: TButton;
    btnNext: TButton;
    btnFirst: TButton;
    btnNew: TButton;
    edtPersonID: TEdit;
    edtSurname: TEdit;
    edtDOB: TEdit;
    Memo1: TMemo;
    procedure btnFirstClick(Sender: TObject);
    procedure btnNewClick(Sender: TObject);
    procedure btnNextClick(Sender: TObject);
    procedure btnTestClick(Sender: TObject);
  private
    { private declarations }
    conn : TMySQL50Connection;
    query : TSQLQuery;
    transaction : TSQLTransaction;
    procedure Display;
  public
    { public declarations }
  end;
var
  Form1: TForm1;
implementation
{ TForm1 }
procedure TForm1.btnTestClick(Sender: TObject);
var
  S: String;
begin
  conn := TMySQL50Connection.Create(nil);
  query := TSQLQuery.Create(nil);
  transaction := TSQLTransaction.Create(nil);
  try
    try
      // Dostosuj do własnego serwera bazy danych, nazwy użytkownika i hasła:
      conn.HostName := '127.0.0.1';
      conn.UserName := 'root';
      conn.Password := '';
      // Jeśli używasz innej nazwy bazy danych, dostosuj tutaj:
      conn.DatabaseName := 'test1';
      conn.Connected := True;
      conn.Transaction := transaction;
      query.DataBase := conn;
      //query.ParseSQL := true;  //linia niepotrzebna - i tak jest to ustawienie domyślne
      //query.ReadOnly := false; //linia niepotrzebna - i tak jest to ustawienie domyślne
      query.SQL.Text := 'select * from tperson';
      query.Open;

      query.Last;
      S := IntToStr(query.RecordCount) + #13#10;
      query.First;

      while not query.EOF do
      begin
        S := S + query.FieldByName('surname').AsString + #13#10;
        query.Next;
      end;
    finally
      //query.Free;
      //conn.Free;
    end;
  except
    on E: Exception do
      ShowMessage(E.message);
  end;
  Memo1.Text:= S;
end;

procedure TForm1.Display;
begin
  edtPersonID.Text := query.FieldByName('personid').AsString;
  edtSurname.Text := query.FieldByName('surname').AsString;
  edtDOB.Text := query.FieldByName('dob').AsString;
end;

procedure TForm1.btnFirstClick(Sender: TObject);
begin
  query.First;
  Display;
end;

procedure TForm1.btnNewClick(Sender: TObject);
begin
  query.Append;
  query.FieldValues['personid'] := edtPersonID.Text;
  query.FieldValues['surname'] := edtSurname.Text;
  query.FieldValues['dob'] := edtDOB.Text;
  query.Post;  
  query.ApplyUpdates; //aby zaktualizować dane w bazie
  transaction.Commit; //Potrzebne od FPC 2.6.4; todo: ktoś powinien sprawdzić, czy to wystarczy
end;

procedure TForm1.btnNextClick(Sender: TObject);
begin
  query.Next;
  Display;
end;

initialization
  {$I unt_db.lrs}
end.

Kontrolki RAD/Databound

Zobacz SQLdb_Tutorial1, SQLdb_Tutorial2 i dalsze samouczki.

Zeos

Zobacz ZeosDBO

[1]

Pascal Data Objects (PDO)

Pascal Data Objects to alternatywna warstwa dostępu do danych, która wydaje się obsługiwać:

• Klientów MySQL 4.0
• Klientów MySQL 4.1
• Klientów MySQL 5.0
• (a także) Firebird 1.5 i 2.0

Obsługiwane są funkcje wprowadzone w MySQL 4.1 i 5.0, takie jak przygotowane instrukcje, powiązania i procedury składowane. PDO jest inspirowane PHP Data Objects. Cały kod i dokumentacja niezbędna do korzystania z tego interfejsu API jest dostępna na sourceforge:

[2]

Pakiet MySQL: moduł niskiego poziomu

Podobnie jak w przypadku wszystkich baz danych, kod SQLDB zależy od specyficznego modułu dla mysql niższego poziomu, która otacza bibliotekę sterownika mysql (.so/.dll). Zwykle używałbyś kodu SQLDB wyższego poziomu, ponieważ umożliwia on szybsze kodowanie, łatwe przełączanie baz danych itp.

Używanie tego jest bardzo łatwe, wszystko, co musisz zrobić, to skompilować kilka modułów i użyć tych modułów w swoim programie. Podczas kompilacji musisz określić lokalizację w systemie plików biblioteki klienta MySQL (libmysqlclient w systemie Linux) i to wszystko.

Dostarczone moduły i programy

W pakiecie znajdują się 3 moduły, z których zwykle potrzebny jest tylko pierwszy:

• mysql - główny moduł mysql.
• mysql<wersja> (np. mysql50) zapewnia dostęp do konkretnej biblioteki mysql dla danej wersji. Uwaga: wersja biblioteki klienta nie jest związana z wersją używanego serwera - z tym wyjątkiem, że chcesz się upewnić, że te wersje są kompatybilne.
• mysql<wersja>com zawiera pewne wewnętrzne procedury MySQL (prawdopodobnie tłumaczenie mysql_com.h); normalnie nie powinno być używane, chyba że chcesz uzyskać dostęp do niektórych typów wewnętrznych.

Przykładowe programy można znaleźć w katalogu <fpc>\packages\mysql\examples.

Instalacja

Interfejs mysql jest rozpowszechniany z pakietami Free Pascal i wraz z dystrybucją kompilatora: Normalnie nie należy podejmować żadnych działań, aby pracować z MySQL.

Jeśli chcesz samodzielnie zmodyfikować i skompilować moduły, źródła mysql znajdują się w katalogu pakietów: packages/mysql

Ten katalog zawiera moduły, program testowy i plik makefile. Przejdź to tego katalogu komendą cd i wpisz

make

Powinno to skompilować moduły. Jeśli kompilacja się powiodła, możesz zainstalować je poleceniem

make install

Następnie możesz przetestować program, uruchamiając

make test

Spowoduje to:

• Uruchomienie skryptu, który utworzy tabelę w bazie danych i wypełni ją danymi. (w tym celu program mysql powinien znajdować się w twojej ścieżce). Domyślnie używana baza danych to testdb.
• Uruchomienie programu testowego testdb
• Ponowne uruchomienie skryptu powłoki, który usunie utworzoną tabelę.

Na ekranie zobaczysz wiele komunikatów, które zawierają informacje zwrotne i wyniki. Jeśli coś poszło nie tak, make poinformuje Cię o tym.

Wróć do Listy Pakietów

Zobacz także

• Najczęęściej zadawane pytania - Więcej o programowaniu baz danych
• SQLdb Samouczek1 - seria samouczków SQLDB, które przeprowadzą Cię przez proces tworzenia działającej aplikacji GUI siatki bazy danych
• Przegląd baz danych Lazarusa - Uruchomienie Lazarusa do pracy z różnymi bazami danych