Write

│ Deutsch (de) │ English (en) │ español (es) │ русский (ru) │
The procedures write and writeLn store a date in a text or typed file. They are defined as part of the Pascal programming language, thus everyone can expect them to work no matter which compiler is used.

In property definitions the reserved word write is used to direct write access. This article deals with the procedures write and writeLn. See object and related articles for the occurrence of write in the context of properties.

Behavior

Signature

Write as well as writeLn share almost the same identical formal signature. However a formal signature is omitted here, since you can not state their signatures in Pascal. Therefore a description follows:

As an optional first parameter a text variable can be specified where data are written to. Write is additionally capable of writing to a typed file variable (file of recordType). If no destination is specified, output is assumed.

Thereafter any number of variables can be specified, but in the case of write at least one has to be present. They have to be char, integer, real, string, or any other data type that can be rendered as (a sequence of) character(s) via implicit typecasts (operator overloading). In the case of typed files as destination, only variables of the file’s record type can be specified.

If the destination is a text file, each data variable identifier may be followed by a colon and a non-negative integer value. This value specifies the minimum width in characters the representation of the respective variable will acquire. It will be padded with space characters, so it becomes right-justified. In {$mode ISO} and {$mode extendedPascal} this value specifies the exact width of Boolean, char and string values, thus 'X':0 will emit nothing.

Floating-point variables may have another colon and non-negative integer value followed, thus two in total, that will specify the number of decimal places after the decimal-period. Also, by the specifying the second format specifier, the default scientific notation is turned off.

Execution

Calling write/writeLn will write the variables’ values to the destination, and if a text variable is the destination, possibly convert them into a representation suitable for humans before doing so.

If the destination file is not open, the run-time error 103 “File not open” will stop program execution. This RTE may be converted to an eInOutErrorr exception if the sysUtils unit is included (via a uses-clause). However, if the destination file is output, no error may be raised at all. You simply will not see any output emitted by write/writeLn calls.

Representation

If the destination is a text file, all ordinal type arguments are converted to human-readable representation. Strings and characters are already considered to be human-readable regardless of their value, e. g. control characters will be written directly without conversion.

Decimal representations of floating-point values may be rounded. All numerical types may be preceded by a negative sign, but a positive sign is never printed.

write will try to convert the value of enumerated types into their canonical names. If such does not exist the run-time error 107 “invalid enumeration” occurs.

program writeDemo(input, output, stderr);

type
	direction = (left, straightOn, right);

var
	heading: direction;
begin
	// 15 characters in total (including period)
	//  6 places after period
	//    rounded
	writeLn(pi():15:6);
	
	heading := straightOn;
	// heading as enumeration will be left-aligned
	// but still use 15 characters
	writeLn(heading:15, '.');
end.

  Note: The default style of formatting numbers may differ depending on whether {$mode ISO} is chosen.

Difference between write and writeLn

writeLn will automatically write a line feed after all other data variables (if any). This line feed is the one suitable for the platform the program runs on. Remember, the notion of “line” applies only for text files.

See also

• system.write and system.writeLn
• Why use Pascal, § “the readLn and writeLn effect”
• read performs the opposite action
• writeStr works like write but outputs into a string