TSplitter/de

│ Deutsch (de) │ English (en) │ suomi (fi) │ français (fr) │ русский (ru) │

Ein vertikaler oder horizontaler Balken auf einem Panel oder Formular platziert, um Unterpanel funktionell zu trennen

TSplitter

Die LCL Komponente TSplitter kann als visuelle Trennlinie zwischen zwei Hälften des Formulars verwendet werden und ermöglicht dem Benutzer diese entweder vertikal oder horizontal zu bewegen. Es ist in der Unit ExtCtrls definiert und befindet sich auf der IDE Komponentenpalette Additional.

TSplitter kann grundsätzlich in zwei verschiedenen Modi arbeiten: über Align (ausrichten - analog Delphi) oder über AnchorSides (nicht von Delphi unterstützt).

Splitter und Align

Align kann für viele einfache Layouts wie zwei Bedienelemente oder einer Reihe von Bedienelementen verwendet werden. Zum Beispiel, wenn sie frei bewegbare Bedienelemente, wie ein Memo oder Listbox benötigen.

Das folgende Beispiel zeigt dies.

Mit Formdesigner

1. erstellen Sie eine neue Form
2. fügen Sie dieser ein TMemo hinzu (zum auswählen Links-Klick auf das TMemo Symbol (Komponentenplatte Standard), dann Links-Klick auf die Form)
3. ändern Sie im Objekt Inspektor die Eigenschaft Align von Memo1 zu alLeft
4. fügen Sie ein TSplitter der Form hinzu
5. das Standard-Align ist bereits alLeft
6. fügen Sie erneut ein TMemo der Form hinzu
7. ändern Sie im Objekt Inspektor das Align von Memo2 zu alClient

Das Gleiche als Code

procedure TMainForm.FormCreate(Sender: TObject);
var
  Memo1: TMemo;
  Splitter1: TSplitter;
  Memo2: TMemo;
begin
  Memo1:=TMemo.Create(Self);
  with Memo1 do begin
    Name:='Memo1';
    Parent:=Self;
    Align:=alLeft;
  end;
  Splitter1:=TSplitter.Create(Self);
  with Splitter1 do begin
    Name:='Splitter1';
    Parent:=Self;
    Left:=1; // position it right of Memo1
    Align:=alLeft;
  end;
  Memo2:=TMemo.Create(Self);
  with Memo2 do begin
    Name:='Memo2';
    Parent:=Self;
    Align:=alClient;
  end;
end;

Splitter mit AnchorSides

AnchorSides (Seitenverankerung) ermöglicht ein feiner abgestimmtes Layout. Align füllt den ganzen Raum. AnchorSides erlauben, Bedienelemente an nebenan liegende Bedienelemente zu verankern.

Mit Formdesigner

1. erstellen Sie eine neue Form
2. fügen Sie dieser ein TMemo hinzu (zum auswählen Links-Klick auf das TMemo Symbol (Komponentenplatte Standard), dann Links-Klick auf die Form)
3. ändern Sie im Objekt Inspektor die Eigenschaft Align von Memo1 zu alLeft
4. fügen Sie ein TSplitter der Form hinzu
5. ändern Sie die Eigenschaft Align von Splitter1 auf alNone
6. Klicken Sie auf Ihrer Form das Memo1 mit einem Rechtsklick an
7. und wählen Sie den Popupmenüpunkt "Ankereditor anzeigen" aus (alternativ: im Objektinspektor Button [...] bei Memo1 -> Anchors)
8. verankern Sie die rechte Seite von Memo1 mit Splitter1
9. fügen Sie erneut ein TMemo der Form hinzu
10. ändern Sie im Objekt Inspektor das Align von Memo2 zu alRight
11. verankern Sie die linke Seite von Memo2 mit Splitter1. Stellen Sie sicher, dass Sie die rechte Seite von Splitter1 verankern (der Button auf dem Anker Editor unter der Combobox)

Das Gleiche als Code

procedure TMainForm.FormCreate(Sender: TObject);
var
  Memo1: TMemo;
  Splitter1: TSplitter;
  Memo2: TMemo;
begin
  Memo1:=TMemo.Create(Self);
  with Memo1 do begin
    Name:='Memo1';
    Parent:=Self;
    Align:=alLeft;
  end;
  Splitter1:=TSplitter.Create(Self);
  with Splitter1 do begin
    Name:='Splitter1';
    Parent:=Self;
    Align:=alNone;
    Left:=100; // some value
    AnchorParallel(akBottom,0,Parent);
  end;
  Memo1.AnchorToNeighbour(akRight,0,Splitter1);
  Memo2:=TMemo.Create(Self);
  with Memo2 do begin
    Name:='Memo2';
    Parent:=Self;
    Align:=alRight;
    AnchorToNeighbour(akLeft,0,Splitter1);
  end;
end;