Lazarus Database Tutorial/it

From Free Pascal wiki
Jump to navigationJump to search

│ Deutsch (de) │ English (en) │ español (es) │ français (fr) │ Bahasa Indonesia (id) │ italiano (it) │ 日本語 (ja) │ Nederlands (nl) │ português (pt) │ русский (ru) │ 中文（中国大陆） (zh_CN) │ 中文（臺灣） (zh_TW) │

Panoramica

Questo tutorial è incentrato sul funzionamento di Lazarus con una serie di database esistenti.

Lazarus supporta di base diversi database; in ogni caso lo sviluppatore deve installare il package adeguato per ciascuno di essi. E' possibile accedere al database attraverso il codice oppure disponendo dei componenti su un form. I componenti data-aware rappresentano i campi del database e vengono collegati impostando la proprietà DataSource in modo che punti ad un TDataSource. Il Datasource rappresenta una table ed è collegato ai componenti del database (per esempio: TPSQLDatabase, TSQLiteDataSet) impostando la proprietà DataSet. I componenti data-aware sono situati nel tab "Data Controls" della palette dei componenti di Lazarus. Il componente Datasource e i componenti dei database sono situati nel tab "Data Access".

Lazarus e MySQL

Far funzionare MySQL su Linux o Windows

Seguite le istruzioni riportate sul MySQL User Manual. Assicuratevi che il daemon mysqld giri correttamente e che tutti i potenziali utenti (inclusi root, mysql, voi stessi e ognuno che ne abbia bisogno) abbiano i privilegi di cui necessitano, da tutti gli host richiesti (inclusi 'localhost', il nome dell'host locale, qualsiasi altro host della vostra rete) per quanto sia consistente con la sicurezza. E' preferibile che tutti gli utenti, incluso il root, abbiano una password. Controllate il funzionamento del sistema del database utilizzando l'esempio fornito nel manuale e assicuratevi che tutti gli utenti abbiano realmente accesso al database.

Far funzionare MySQL con FPC in modalità testuale

C'è una directory con un programma di esempio in $(fpcsrcdir)/packages/base/mysql/. Potete trovare la directory dei sorgenti del fpc in Lazarus: Environment menu -> Environment Options -> Paths tab -> FPC source directory. Alcuni percorsi tipici per la directory di mysql sono /usr/share/fpcsrc/packages/base/mysql/ (rpm install) oppure C:\lazarus\fpcsrc\packages\base\mysql\ (windows). Questa directory contiene anche le units mysql.pp, mysql_com.pp e mysql_version.pp. Prima di avviare lo script per il test, avrete bisogno di creare un database chiamato testdb: è possibile fare ciò loggandosi nel monitor mysql (come root con pieni privilegi) e immettendo la seguente linea SQL 

CREATE DATABASE testdb;

quindi assicurandovi che tutti gli utenti abbiano i privilegi di accesso appropriati 

GRANT ALL ON testdb TO johnny-user IDENTIFIED BY 'johnnyspassword';

Esiste uno script chiamato mkdb che ora dovreste provare a lanciare: 

sh ./mkdb

Probabilmente restituirà un errore, poiché il sistema non permette ad utenti anonimi di accedere al database. Quindi modificate lo script utilizzando un editor di testo in modo tale che la linea che chiama mysql sia: 

mysql -u root -p  ${1-testdb} << EOF >/dev/null

e provate a lanciarlo di nuovo, immettendo la vostra password quando richiesto. Con un pizzico di fortuna dovreste essere in grado di creare il database di test: provatelo (loggati nel monitor mysql) lanciando la sequenza di comandi mysql 

select * from FPdev;

Dovreste vedere una tabella contenente l'ID, lo username e l'indirizzo email di alcuni degli sviluppatori del FPC.

Ora provate a lanciare il programma di test testdb.pp (potrebbe essere necessario compilarlo, e quasi sicuramente non andrà a buon fine al primo tentativo!!).

Ho scoperto che il programma potrebbe non connettersi a mysql per diverse ragioni:

  • Il mio sistema (SuSE Linux v9.0) installa mysql v4.0.15, non la versione 3 per la quale il package è stato disegnato.
  • Il programma ha bisogno di avere nome utente e password per accedere al database.
  • Il compilatore ha bisogno di sapere dove trovare le librerie di mysql (NEL CASO IN CUI NON ABBIATE PROVVEDUTO AD INSTALLARE LE LIBRERIE DI SVILUPPO DI MYSQL, FATELO ORA!)

Ho creato una copia di testdb.pp chiamandola trydb.pp, piuttosto che modificare l'originale - questo significa che i files originali verranno ancora corretti durante gli aggiornamenti successivi da CVS. Ho anche cpiato i files trovati nella sottodirectory mysql/ver40/ nella sottodirectory principale mysql/, rinominandoli mysql_v4.pp, mysql_com_v4.pp e mysql_version_v4.pp, assicurandomi di rinominare le units all'interno di ogni file in maniera corrispondente. Ho cambiato il blocco uses in trydb.pp in 

uses mysql_v4

e quello in mysql_v4.pp in 

uses mysql_com_v4

Ho aggiunto una linea a /etc/fpc.cfg per far puntare il compilatore alle mie librerie: 

-Fl/lib;/usr/lib

I passi seguenti potrebbero non essere necessari se le librerie di sviluppo sono state installate, poiché i collegamenti vengono creati automaticamente, ma controllare non fa mai male. Ho dovuto trovare il vero nome della libreria mysqlclint in /usr/lib e, nel mio caso, ho dovuto lanciare il comando da shell: 

ln -s libmysqlclient.so.12.0.0 lmysqlclient

per creare un link simbolico che permettesse a FPC di trovare la libreria. Per buona pratica ho anche creato il link 

ln -s libmysqlclient.so.12.0.0 mysqlclient

e posizionato link simili in altre directory: non strettamente necessario, solo per sicurezza...! Alcuni utenti potrebbero aver bisogno di aggiungere il seguente link: 

ln -s libmysqlclient.so.12.0.0 libmysqlclient.so

Ho modificato trydb.pp in modo da includere i dettagli dell'utente, inizialmente aggiungendo l'host, l'user e la password come costanti: 

 const
   host : Pchar= 'localhost';
   user : Pchar= 'myusername';
   passwd: Pchar = 'mypassword';

Ho anche scoperto che non posso connettermi a mysql utilizzando mysql_connect(), ma ho dovuto utilizzare mysql_real_connect() che ha molti più parametri. Per complicare le cose ulteriormente il numero di parametri sembra essere cambiato tra la versione 3 (dove erano sette) e la versione 4 (dove sono otto). Prima di utilizzare mysql_real_connect ho dovuto utilizzare mysql_init() che non esiste nel file mysql.pp originale, ma esiste in mysql_v4.pp.

Quindi il codice per la connessione al database è: 

 { a few extra variables}
 var
   alloc : PMYSQL;
  
 {main program fragment}
  
 begin
  if paramcount=1 then
    begin
    Dummy:=Paramstr(1)+#0;
    DataBase:=@Dummy[1];
    end;
  
 Writeln ('Allocating Space...');
  alloc := mysql_init(PMYSQL(@qmysql));
  Write ('Connecting to MySQL...');
  sock :=  mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
  if sock=Nil then
    begin
    Writeln (stderr,'Couldn''t connect to MySQL.');
    Writeln (stderr, 'Error was: ', mysql_error(@qmysql));
    halt(1);
    end;
  Writeln ('Done.');
  Writeln ('Connection data:');
 {$ifdef Unix}
  writeln ('Mysql_port      : ',mysql_port);
  writeln ('Mysql_unix_port : ',mysql_unix_port);
 {$endif}
  writeln ('Host info       : ',mysql_get_host_info(sock));
  writeln ('Server info     : ',mysql_stat(sock));
  writeln ('Client info     : ',mysql_get_client_info);
  
  Writeln ('Selecting Database ',DataBase,'...');
  if mysql_select_db(sock,DataBase) < 0 then
    begin
    Writeln (stderr,'Couldn''t select database ',Database);
    Writeln (stderr,mysql_error(sock));
    halt (1);
    end;
 {... as original contents of testdb.pp}

Ora siete pronti per compilare trydb.pp? 

 fpc trydb

fatto! Adesso lanciatelo: 

 ./trydb

whoopee! Ho ottenuto l'elenco degli sviluppatori del FPC!

Alcuni ulteriori perfezionamenti: rendete interattive l'immissione dei dettagli dell'utente e l'immissione dei comandi, utilizzando variabili piuttosto che costanti, e permettete di inserire diversi comandi SQL, finché non viene rovato il comando quit: controllate il listato completo del programma, dove i dettagli dell'utente sono inseriti da console, e il programma va in un loop dove i comandi SQL sono inseriti sempre da console (senza il punto e virgola finale) e le risposte vengono mostrate a schermo solo quando 'quit' viene inserito dalla tastiera.

Vedi Sample Console Listing.

Connettersi a MySQL da un'Applicazione Lazarus

Questo tutorial mostra come connettere Lazarus a un database MySQL ed eseguire delle semplici interrogazioni, utilizzando solo i componenti di base di Lazarus; non vengono utilizzati componenti Data Aware, ma vengono illustrati i principi dell'interfacciamento con il database.

Create un nuovo progetto in Lazarus: 

Project -> New Project -> Application

Apparirà un nuovo form generato automaticamente.

Ingrandite il form in modo tale che riempia circa metà schermo, quindi rinominate il form e la caption in 'TryMySQL'.

Dal tab dei componenti Standard posizionate tre Edit Box nella parte in alto a sinistra del Form e, immediatamente sopra ogni box, posizionate una label. Cambiate name e captions in 'Host' (e HostLLabel, HostEdit), 'UserName' (e UserLabel, UserEdit) e 'Password' (con PasswdLabel e PasswdEdit). In alternativa potreste utilizzare il componente LabelledEdit dal tab Additional.

Selezionate l'Edit box Passwd e trovate la proprietà PasswordChar: cambiatela in '*' o in un altro carattere, in modo che quando digiterete una password i caratteri non appariranno sullo schermo, ma verrà mostrata una serie di *. Assicuratevi che la proprietà Text di ogni edit box sia vuota.

Ora posizionate un altro Edit box e un'altra label nell'angolo in alto a destra del form. Cambiate il testo della label in 'Enter SQL Command' e chiamate l'edit box CommandEdit.

Mettete tre Button sul form: due a sinistra sotto gli Edit box e uno a destra, sotto il command box.

Cambiate il testo dei button sulla sinistra in 'Connect to Database' (ConnectButton) e 'Exit' (ExitButton) e il testo di quello a destra in 'Send Query' (QueryButton).

Posizionate un grande Memo Box con una label con il testo 'Results' (ResultMemo) nella parte inferiore destra del form, in modo tale da riempire quasi tutto lo spazio disponibile. Cambiate la proprietà ScrollBars in ssAutoBoth in modo che le scroll bar appaiano automaticamente se il testo riempie lo spazio. Mettete la proprietà WordWrap a True.

Posizionate unoa Status Bar (dal tab Common Controls) nella parte bassa del form e cambiate la sua proprietà SimpleText in 'TryMySQL'.

Uno screenshot del form può essere visualizzato da qui: Mysql Example Screenshot

Ora abbiamo bisogno di gestire alcuni eventi.

I tre Edit box sulla sinistra serviranno per immettere hostname, username e password. Quando sono stati inseriti, viene premuto il tasto Connect. L'evento OnClick del button è basato su parte del programma FPC in modalità testuale che abbiamo appena visto.

Le risposte dal database ora non possono essere scritte con l'ausilio dei comandi pascal write o writeln: piuttosto, le risposte devono essere convertite in string e mostrate nel Memo box. Laddove i comandi Pascal write e writeln sono in grado di effettuare diverse conversioni di tipo 'al volo', l'utilizzo di una memo box per l'output di testo necessita di una conversione esplicita dei tipi di dato in string, così le variabili di tipo Pchar devono essere convertite in string mediante StrPas, gli integer tramite IntToStr.

Le string vengono mostrate nel Memo box tramite l'utilizzo di 

 procedure ShowString (S : string);
 (* display a string in a Memo box *)
 begin
        trymysqlForm1.ResultsMemo.Lines.Add (S)
 end;

Così l'evento onClick del ConnectButton diventa: 

 procedure TtrymysqlForm1.ConnectButtonClick(Sender: TObject);
 (* Connect to MySQL using user data from Text entry boxes on Main Form *)
 var 
   strg: string;
 begin
   dummy1 :=  trymysqlForm1.HostEdit.text+#0;
   host := @dummy1[1];
   dummy2 := trymysqlForm1.UserEdit.text+#0;
   user := @dummy2[1];
   dummy3 := trymysqlForm1.PasswdEdit.text+#0;
   passwd := @dummy3[1];
  
   alloc := mysql_init(PMYSQL(@qmysql));
   sock :=  mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
   if sock=Nil then
   begin
     strg :='Couldn''t connect to MySQL.'; showstring (strg);
     Strg :='Error was: '+ StrPas(mysql_error(@qmysql)); showstring (strg);
   end else
   begin
     trymysqlForm1.statusBar1.simpletext := 'Connected to MySQL';
     strg := 'Now choosing database : ' + database; showstring (strg);
   {$ifdef Unix}
     strg :='Mysql_port      : '+ IntToStr(mysql_port); showstring (strg);
     strg :='Mysql_unix_port : ' + StrPas(mysql_unix_port); showstring (strg);
   {$endif}
     Strg :='Host info       : ' + StrPas(mysql_get_host_info(sock));
     showstring (strg);
     Strg :='Server info     : ' + StrPas(mysql_stat(sock)); showstring (strg);
     Strg :='Client info     : ' + Strpas(mysql_get_client_info);  showstring (strg);
  
     trymysqlForm1.statusbar1.simpletext := 'Selecting Database ' + DataBase +'...';
     if mysql_select_db(sock,DataBase) < 0 then
     begin
       strg :='Couldn''t select database '+ Database; ShowString (strg);
       Strg := mysql_error(sock); ShowString (strg);
     end
   end;
 end;

Il Text Box sulla destra permette l'inserimento di un comando SQL, senza il punto e virgola finale; quando si è soddisfatti della query inserita, viene premuto il tasto SendQuery e la query viene processata, il cui risultato verrà mostrato nel box ResultsMemo.

Il gestore di eventi SendQuery è ancora una volta basato sulla versione in modalità testo, con l'eccezione che, anche qui, si abbia una conversione esplicita di tipo prima di mostrare le string nel box.

Una differenza con il programma in modalità testuale è che, nel caso in cui venga riscontrata una anomalia, il programma non viene terminato e la connessione a MySQL non viene chiusa; invece viene restituito il controllo al form principale e viene data l'opportunità di correggere la query prima di lanciarla di nuovo. L'applicazione viene chiusa (con la chiusura della connessione a MySQL) solo quando il tasto Exit viene premuto.

Questo è il codice per SendQuery: 

 procedure TtrymysqlForm1.QueryButtonClick(Sender: TObject);
 var
   dumquery, strg: string;
 begin
   dumquery := TrymysqlForm1.CommandEdit.text;
   dumquery := dumquery+#0;
   query := @dumquery[1];
   trymysqlForm1.statusbar1.simpletext := 'Executing query : '+ dumQuery +'...';
   strg := 'Executing query : ' + dumQuery; showstring (strg);
   if (mysql_query(sock,Query) < 0) then
   begin
     Strg :='Query failed '+ StrPas(mysql_error(sock)); showstring (strg);
   end else
   begin
    recbuf := mysql_store_result(sock);
    if RecBuf=Nil then
    begin
      Strg :='Query returned nil result.'; showstring (strg);
    end else
    begin
      strg :='Number of records returned  : ' + IntToStr(mysql_num_rows (recbuf));
      Showstring (strg);
      Strg :='Number of fields per record : ' + IntToStr(mysql_num_fields(recbuf));
      showstring (strg);
      rowbuf := mysql_fetch_row(recbuf);
      while (rowbuf <>nil) do
      begin
        Strg :='(Id: '+ rowbuf[0]+', Name: ' + rowbuf[1]+ ', Email : ' +
        rowbuf[2] +')';
        showstring (strg);
        rowbuf := mysql_fetch_row(recbuf);
      end;
    end;
  end;
 end;

Salvate il progetto e lanciate Run -> Run.

Scaricare il codice sorgente MYSQL

Un listato completo del programma è disponibile qui: Sample Source Code

Semplice Demo MySQL sull'utilizzo del componente TMySQL50Connection

Il seguente codice è una demo veloce su come operare in maniera semplice (testato su Win XP con Lighty2Go). libmysql.dll è stata copiata nelle directory del progetto e di lazarus.exe (disponibile in una directory in Lighty2Go). Non è richiesto il posizionamento sul form di altri componenti aggiuntivi oltre che di tre edit box, un memo box e alcuni button. C'è bisogno di aggiungere mysql50conn e sqldb nella clausola uses. La directory dei componenti di Lazarus deve essere rw per il programmatore. Il dbms mysql utilizzato ha come user 'root' e non è impostata nessuna password; un database test1 con una tabella tPerson contenente tre campi: personid (int), surname (varchar(40)) e dob (datetime). E' stato utilizzato phpMyAdmin (in Lighty2Go) per creare il db, la tabella, i campi e per inserire alcuni dati. Da notare che le date in phpMyAdmin devono essere inserite nel formato YYYY-MM-DD, benché il programma che stiamo creando accetti le date nei formati usuali. Il button btnTest deve essere cliccato per primo, perché crea la connessione con il dbms. Notare la linea che applica gli aggiornamenti - senza di essa i dati modificati o immessi nono verranno scritti sul db anche se risiedono in memoria e possono essere visualizzati tramite btnFirst e btnNext. 

unit unt_db;
//Example based on:
//http://www.lazarus.freepascal.org/index.php?name=PNphpBB2&file=viewtopic&t=5761
//from tpglemur on that forum
{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  mysql50conn, sqldb, StdCtrls;
type
  { TForm1 }
  TForm1 = class(TForm)
    btnTest: TButton;
    btnNext: TButton;
    btnFirst: TButton;
    btnNew: TButton;
    edtPersonID: TEdit;
    edtSurname: TEdit;
    edtDOB: TEdit;
    Memo1: TMemo;
    procedure btnFirstClick(Sender: TObject);
    procedure btnNewClick(Sender: TObject);
    procedure btnNextClick(Sender: TObject);
    procedure btnTestClick(Sender: TObject);
  private
    { private declarations }
    conn : TMySQL50Connection;
    query : TSQLQuery;
    transaction : TSQLTransaction;
    procedure Display;
  public
    { public declarations }
  end;
var
  Form1: TForm1;
implementation
{ TForm1 }
procedure TForm1.btnTestClick(Sender: TObject);
var
  S: String;
begin
  conn := TMySQL50Connection.Create(nil);
  query := TSQLQuery.Create(nil);
  transaction := TSQLTransaction.Create(nil);
  try
    try
      conn.HostName := '127.0.0.1';
      conn.UserName := 'root';
      conn.Password := '';
      conn.DatabaseName := 'test1';
      conn.Connected := True;
      conn.Transaction := transaction;
      query.DataBase := conn;
      //query.ParseSQL := true; //line not needed - this is the default anyway
      //query.ReadOnly := false; //line not needed - this is the default anyway
      query.SQL.Text := 'select * from tperson';
      query.Open;

      query.Last;
      S := IntToStr(query.RecordCount) + #13#10;
      query.First;

      while not query.EOF do
      begin
        S := S + query.FieldByName('surname').AsString + #13#10;
        query.Next;
      end;
    finally
      //query.Free;
      //conn.Free;
    end;
  except
    on E: Exception do
      ShowMessage(E.message);
  end;
  Memo1.Text:= S;
end;

procedure TForm1.Display;
begin
  edtPersonID.Text := query.FieldByName('personid').AsString;
  edtSurname.Text := query.FieldByName('surname').AsString;
  edtDOB.Text := query.FieldByName('dob').AsString;
end;

procedure TForm1.btnFirstClick(Sender: TObject);
begin
  query.First;
  Display;
end;

procedure TForm1.btnNewClick(Sender: TObject);
begin
  query.Append;
  query.FieldValues['personid'] := edtPersonID.Text;
  query.FieldValues['surname'] := edtSurname.Text;
  query.FieldValues['dob'] := edtDOB.Text;
  query.Post;  
  query.ApplyUpdates; //to apply update
  //transaction.Commit; //line not needed
end;

procedure TForm1.btnNextClick(Sender: TObject);
begin
  query.Next;
  Display;
end;

initialization
  {$I unt_db.lrs}
end.

Questa versione utilizza i componenti TMySQL50Connection, TSQLQuery, TSQLTransaction, TDatasource e TDBGrid preventivamente posizionati sul form: 

unit unt_mysql2;
{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  mysql50conn, sqldb, StdCtrls, db, DBGrids, DbCtrls;
type
  { TForm1 }
  TForm1 = class(TForm)
    btnConnect: TButton;
    btnSave: TButton;
    btnNext: TButton;
    btnPrior: TButton;
    Datasource1: TDatasource;
    DBGrid1: TDBGrid;
    Memo1: TMemo;
    MySQL50Connection1: TMySQL50Connection;
    SQLQuery1: TSQLQuery;
    SQLTransaction1: TSQLTransaction;
    procedure btnConnectClick(Sender: TObject);
    procedure btnNextClick(Sender: TObject);
    procedure btnPriorClick(Sender: TObject);
    procedure btnSaveClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end; 
var
  Form1: TForm1; 
implementation
{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  //Set properties of components:
  //(could be done in the Object Inspector)
  MySQL50Connection1.HostName := '127.0.0.1';
  MySQL50Connection1.UserName := 'root';
  MySQL50Connection1.Password := '';
  MySQL50Connection1.DatabaseName := 'test1';
  MySQL50Connection1.Transaction := SQLTransaction1;
  //SQLQuery1.ParseSQL := true; //line not needed - this is the default
  //SQLQuery1.ReadOnly := false; //line not needed - this is the default
  SQLQuery1.SQL.Text := 'select * from tperson';
  SQLQuery1.Transaction := SQLTransaction1;
  SQLQuery1.UpdateMode := upWhereChanged;
  Datasource1.Dataset := SQLQuery1;
  DBGrid1.DataSource := Datasource1;;
end;

procedure TForm1.btnConnectClick(Sender: TObject);
var
 S : string;
begin
  try
    MySQL50Connection1.Connected := true;
    SQLQuery1.Open;

    //Tests to see if all is OK:
    SQLQuery1.Last;
    S := IntToStr(SQLQuery1.RecordCount) + #13#10;
    SQLQuery1.First;
    while not SQLQuery1.EOF do
    begin
      S := S + SQLQuery1.FieldByName('surname').AsString + #13#10;
      SQLQuery1.Next;
    end;
  except
    on E: Exception do
      ShowMessage(E.message);
  end;
  Memo1.Text:= S;
end;

procedure TForm1.btnNextClick(Sender: TObject);
begin
  SQLQuery1.Next;
end;

procedure TForm1.btnPriorClick(Sender: TObject);
begin
  SQLQuery1.Prior;
end;

procedure TForm1.btnSaveClick(Sender: TObject);
begin
  SQLQuery1.ApplyUpdates;
end;

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  //Required or get EDatabase error on close:
  MySQL50Connection1.Connected := false;
end;

initialization
  {$I unt_mysql2.lrs}
end.

Lazarus e PostgreSQL

Questa è una guida molto breve che spiega come connettere Lazarus 0.9.12 o successivo a un database PostgreSQL, locale o remoto, tramite l'utilizzo di TPQConnection.

Dopo avere correttamente installato il package, seguite questi passi:

  • Posizionare un PQConnection dal tab SQLdb
  • Posizionare un SQLQuery dal tab SQLdb
  • Posizionare un SQLTransaction dal tab SQLdb
  • Posizionare un DataSource dal tab DataAccess
  • Posizionare un DBGrid dal tab DataControls
  • In PQConnection modificare le proprietà:
    • transaction con il rispettivo oggetto SQLTransaction
    • Database name
    • HostName
    • UserName + password
  • Assicurarsi che SQLTransaction sia cambiato automaticamente per puntare a PQConnection
  • In SQLQuery modificare le proprietà:
    • transaction con il rispettivo oggetto
    • database con il rispettivo oggetto
    • SQL (qualcosa del tipo 'select * from anytable')
  • Nell'oggetto DataSource assegnate alla proprietà DataSet l'oggetto SQLQuery
  • In DBGrid assegnate alla proprietà datasource l'oggetto DataSource

Posizionare tutti gli switch su connected e active e la DBGrid dovrebbe essere riempita a design time. TDBText e TDBEdit sembrano funzionare, ma (per me) _mostrano_ _dati_ solamente.

Per cambiare i contenuti nel database, ho chiamato direttamente il motore DB con il seguente codice: 

  try
    sql:= 'UPDATE table SET setting=1';
    PQDataBase.Connected:=True;
    PQDataBase.ExecuteDirect('Begin Work;');
    PQDataBase.ExecuteDirect(sql);
    PQDataBase.ExecuteDirect('Commit Work;');
    PQDataBase.Connected:=False;
  except
    on E : EDatabaseError do
      MemoLog.Append('DB ERROR:'+sql+chr(13)+chr(10)+E.ClassName+chr(13)+chr(10)+E.Message);
    on E : Exception do
      MemoLog.Append('ERROR:'+sql+chr(13)+chr(10)+E.ClassName+chr(13)+chr(10)+E.Message);
  end;
  • Note:
    • Controllato su windows, Lazarus 0.9.12 + PgSQL 8.3.1
    • Alcune prove su linux, Lazarus 0.9.12 and PgSQL 8.0.x


  • Installazione e errori:
    • Nella verione .12 di Lazarus che ho provato, i campi del tipo "text" e "numeric" hanno dei bugs
    • Ho usato senza problemi char fixed size, int e float8
    • Alcune volte riavviare Lazarus risolve stupidi errori...
    • Dopo alcuni errori, le transaczioni rimangono attive e devono essere disattivate a mano
    • Le modifiche fatte in Lazarus ovviamente non sono visibili finché la transazione non viene passata
    • Il debugger integrato sembra buggato (almeno in windows) - alcune volte far girare l'eseguibile fuori dall'ide può aiutare a scovare errori
    • In linux alcuni messaggi d'errore vengono mostrati nella console -- lanciate il vostro programma da linea di comando, alcune volte ci sono ulteriori informazioni di debug molto utili
    • Error: "Can not load Postgresql client. Is it installed (libpq.so) ?"
      • Aggiungete il percorso per trovare libpq* dall'installazione di PostgreSQL.
      • In linux aggiungete il percorso per trovare il file libpq.so alla sezione delle librerie nel vostro file /etc/fpc.cfg. Per esempio: -Fl/usr/local/pgsql/lib
      • In windows, aggiungete queste librerie dove volete, in una directory indicata nella variabile d'ambiente Path o nella directory del progetto
      • In windows, ho copiato tutte le dll presenti in C:\Program Files\PostgreSQL\8.1\bin in un'altra directory segnata in PATH
      • Oppure aggiungete la directory postgres\bin al path

Un buon esempio sulla connessione tra Lazarus e PostgreSQL sotto Windows è easyDB.

Lazarus e SQLite

di Luiz Américo

Visitate la homepage di sqlite4fpc per ottenere l'API reference e altre guide.

Introduzione

TSqliteDataset e TSqlite3Dataset sono dei discendenti di TDataset che permettono l'accesso, rispettivamente, ai database sqlite 2.8.x e 3.x.x. Di seguito un elenco dei suoi principali vantaggi e svantaggi:

Vantaggi:

  • Flessibilità: il programmatore può scegliere se usare o meno il linguaggio SQL, dando l'opportunità di lavorare su strutture formate da semplici tabelle o su strutture di qualsiasi complessità permesse da SQL/sqlite
  • Aggiornamento automatico del database: nessun bisogno di aggiornare manualmente il database con comandi SQL; un singolo metodo si occupa di farlo
  • Velocità: i dati vengono cacheati in memoria, per velocizzare la navigazione nel dataset
  • Nessuna installazione/configurazione del server: una semplice dll da distribuire assieme al vostro eseguibile

Svantaggi:

  • Richiede un file esterno (la libreria sqlite)

Requisiti

  • Per il database sqlite2:
    • fpc 2.0.0
    • Lazarus 0.9.10
    • sqlite runtime library 2.8.15 o successivo (scaricabile da www.sqlite.org)
  • Per il database sqlite3:
    • fpc 2.0.2
    • Lazarus 0.9.11 (revisione svn 8443 o seguente)
    • sqlite runtime library 3.2.1 o successivo (scaricabile da www.sqlite.org)

Prima di iniziare un progetto lazarus, assicuratevi che:

  • la libreria sqlite sia nel PATH di sistema o nella directory dell'eseguibile
  • in Linux, indicate cmem come prima unit nella clausola uses del programma principale
    • In Debian, Ubuntu e in altre distribuzioni Debian-like, per eseguire il build dell'IDE di Lazarus c'è bisogno di installare i package libsqlite-dev/libsqlite3-dev, oltre a sqlite/sqlite3 (vale anche per OpenSuSe)

Come utilizzare SQLite (utilizzo di base)

Installate il package che trovate nella directory /components/sqlite (qui le istruzioni)

A design time impostate le seguenti proprietà:

  • FileName: percorso del database sqlite [richiesto]
  • TableName: nome della table utilizzata nel comando sql [richiesto]
  • Sql: un comando select SQL [opzionale]

Creare una Table (Dataset)

Doppio click sull'icona del componente o utilizzate la voce 'Create Table' dal menu popup che compare cliccando col tasto destro del mouse sull'icona del componente. Verrà visualizzato un semplice editor di table. 

 Questi sono tutti i tipi di campi supportati da TSqliteDataset e TSqlite3Dataset: 
 
 Integer
 AutoInc
 String
 Memo
 Bool 
 Float
 Word
 DateTime
 Date
 Time
 LargeInt
 Currency

Recuperare dati

Dopo aver creato la table o con una table creata in precedenza, aprite il dataset col metodo Open. Se la proprietà SQL non è stata impostata, allora verranno recuperati tutti i records da tutti i campi; stessa cosa se SQL è impostato a: 

 SQL := 'Select * from TABLENAME';

Applicare le modifiche al datafile

Per utilizzare la funzione ApplyUpdates, il dataset deve contenere almeno un campo che risponda ai requisiti di una Primary Key (i valori devono essere UNIQUE e non NULL)

E' possibile fare questo in due modi:

  • Impostando la proprietà PrimaryKey al nome del campo Primary Key
  • Aggiungendo un campo AutoInc (questo metodo è più semplice, poiché TSqliteDataSet lo gestisce automaticamente come Primary Key)

Se una delle due condizioni è soddisfatta basterà chiamare 

 ApplyUpdates;

PS1: se entrambe le condizioni sono impostate, il campo corrispondente al PrimaryKey viene utilizzato per apportare le modifiche.

PS2: Impostare come PrimaryKey un campo che non lo è porterà ad una perdita di dati chiamando ApplyUpdates, quindi assicuratevi che il campo scelto contenga valori non Null e Unique prima di usarlo.

Note

  • Benché sia stato testato con 10000 records ed abbia funzionato, TSqliteDataset mantiene tutti i dati in memoria, quindi ricordatevi di recuperare solo i dati necessari (principalmente con in campi Memo).
  • Lo stesso datafile (proprietà Filename) può contenere diverse table/dataset
  • Diversi dataset (diverse combinazioni di field) possono essere create utilizzando la stessa table contemporaneamente
  • E' possibile filtrare i dati tramite il comando SQL WHERE, chiudendo e riaprendo il dataset (o chiamando il metodo RefetchData). Ma in questo caso, l'ordine e il numero dei campi deve rimanere lo stesso
  • E' anche possibile utilizzare comandi SQL complessi come aliases, joins, views in table multiple (ricordate che devono risiedere nello stesso datafile), ma in questo caso ApplyUpdates non funzionerà. Se avete bisogno di utilizzare query complesse e di applicare le modifiche al datafile, inviatemi una mail e vi invierò alcuni consigli su come farlo
  • E' possibile impostare il filename ad un datafile sqlite2.x non creato con TSqliteDataset e aprirlo, ma alcuni per alcuni campi non verrà riconosciuto correttamente il tipo. Verranno trattati come campi stringa.

Alcuni esempi generici possono essere trovati nella directory CVS fpc/fcl/db/sqlite

Luiz Américo pascalive(at)bol(dot)com(dot)br

Lazarus e MSSQL

Funziona tramite Zeoslib (ultima versione da CVS). Controllate i link in fondo alla pagina.

Alternativamente, è possibile accedere ai database MSSQL via ODBC - senza nessun bisogno di installare Zeoslib o altre librerie aggiuntive - basta utilizzare il componente SQLdb incluso (l'ho testato con Lazarus v0.9.26.2)

Il codice di esempio qui sotto seleziona le righe da una tabella chiamata 'journal_entries' e mostra tutti i valori della colonna 'journal_entry' in un controllo Memo chiamato Memo1. 

 procedure TForm1.Button1Click(Sender: TObject);
 var
   S: String;
   conn: TODBCConnection;
   query: TSQLQuery;
   transaction: TSQLTransaction;
 
 begin
   conn := TODBCCOnnection.Create(nil);
   query := TSQLQuery.Create(nil);
   transaction := TSQLTransaction.Create(nil);
   try
     try
       conn.HostName := '127.0.0.1';
       conn.DatabaseName := 'diary'; {replace this with the name of your database}
       conn.Transaction := transaction;
       conn.UserName:= 'db_username';
       conn.Password:= '';
       query.DataBase := conn;
       query.UsePrimaryKeyAsKey:=false; {required, else you get "could not retrieve primary 
                                         key metadata". I was really stuck on this until I found 
                                         http://bugs.freepascal.org/view.php?id=13241}
       query.SQL.Text := 'select * from diary.dbo.journal_entries';
       query.Open; 
       S := '';
       while not query.EOF do
       begin
         S := S + query.FieldByName('journal_entry').AsString + #13#10;
         query.Next;
       end;
     finally
       query.Free;
       conn.Free;
     end;
   except
     on E: Exception do
       ShowMessage(E.message);
   end;
   Memo1.Text:= S;
 end;

Lazarus e Interbase / Firebird

Controllate Install Packages. In questa pagina c'è un piccolo esempio iniziale con una spiegazione su come connettersi a un server IB o FB.

Funziona Zeoslib anche con l'ultima versione di Zeoslib (dal CVS).

Libreria FBLib per Firebird

[1] è una libreria Open Source Non Data Aware per l'accesso diretto al Database Relazionale Firebird da Borland Delphi / Kylix, Freepascal e Lazarus.

Caratteristiche attualmente implementate:

  • Accesso diretto a Firebird 1.0.x 1.5.x Classic o SuperServer
  • Multipiattaforma [Win32, Gnu/Linux, FreeBSD)
  • Selezione automatica della libreria client 'fbclient' o 'gds32'
  • Query con parametri
  • Supporto del dialetto 1/3 di SQL
  • Licenza LGPL
  • Estrazione di metadata
  • Semplice parser di script
  • Solo 100-150 KB aggiunti al file EXE finale
  • Supporto dei campi BLOB
  • Esportazione dei dati in HTML SQL Script
  • Service manager (backup, ripristino, gfix...)
  • Events Alerter

Potete scaricare la documentazione dal sito di FBLib.

Lazarus e dBase

Tony Maro

Potete anche visitare la pagina TDbf Tutorial

FPC include un semplice componente per database che funziona in modo simile al componente TTable di Delphi, chiamato "TDbf" (TDbf Website) che supporta un sottoinsieme base di caratteristiche per la gestione di files dBase. Non viene installato di default, quindi per prima cosa dovrete installarne il package dalla directory "lazarus/components/tdbf" ed eseguire il rebuild dell'IDE di Lazarus. Comparirà quindi vicino al componente TDatasource nella palette dei componenti (tab Data Access).

Il componente TDbf ha un vantaggio rispetto ad altri componenti per database nel fatto che non richiede nessun tipo di motore database a runtime; comunque non rappresenta la migliore alternativa per applicazioni con database molto grandi.

E' molto semplice da utilizzare: basta posizionare un TDbf sul form, impostare il percorso della directory dove si trovano i files del vostro database, impostare il nome della table e collegarlo ad un componente TDatasource.

Funzionalità più avanzate richiedono uno sforzo maggiore. Se una table non esiste, avrete bisogno di crearla in qualche modo, a meno che non ci sia qualche table designer compatibile di cui non sono a conoscenza. Nota: la versione corrente di OpenOffice (2.0x) contiene OpenOffice Base, che può creare files dbf in maniera molto semplice.

Provare ad aprire una table non esistente genererà un errore. Le table possono essere create tramite il componente dopo aver impostato il runtime path e il nome della table.

Per esempio, per creare una table chiamata "dvds" per gestire la vostra collezione di dvd dovrete posizionare il componente su un form, impostare il runtime path e modificare il table name in "dvds". Il risultante file del database verrà chiamato "dvds.dbf".

Nel codice, inserite quanto segue: 

  Dbf1.FilePathFull := '/path/to/my/database';
  Dbf1.TableName := 'dvds';
  With Dbf1.FieldDefs do begin
    Add('Name', ftString, 80, True);
    Add('Description', ftMemo, 0, False);
    Add('Rating', ftString, 5, False);
  end;
  Dbf1.CreateTable;

Quando farete girare il programma, la table della vostra collezione di DVD verrà creata. Dopo di ciò, tutti i componenti data aware collegati tramite il TDatasource a questo componente permetteranno di accedere facilmente ai dati.

Aggiungere un indice risulta un po' differente da come si gestisce una TTable classica. Deve essere fatto dopo che il database è stato aperto. E' anche lo stesso metodo usato per ricostruire gli indici. Per esempio: 

  Dbf1.Exclusive := True;
  Dbf1.Open;
  Dbf1.AddIndex('dvdsname','Name',[ixPrimary, ixUnique, ixCaseInsensitive]);
  Dbf1.AddIndex('rating.ndx', 'Rating', [ixCaseInsensitive]);
  Dbf1.Close;

Il primo (primary) indice sarà un file chiamato "dvdsname.mdx" e il secondo sarà un file chiamato "rating.ndx", quindi in un database su diverse table dovrete fare attenzione a non utilizzare lo stesso nome di file più di una volta.

Proverò ad aggiungere un esempio più articolato in seguito, ma spero che questo permetterà ai vecchi programmatori Delphi di cominciare a lavorare con i database in Lazarus!


Ricerca e Visualizzazione di un insieme di dati

Simon Batty

In questo esempio ho provato a fare una ricerca su un database di libri per tutti i titoli di un autore e a mostrarli in una memo box 

  Dbf1.FilePathFull := '/home/somelocatio/database_location/'; // path to the database directory
  Dbf1.TableName := 'books.dbase';                             // database file (including extension)
  DbF1.Open;
  memo1.Clear;                                                 // clear the memo box
  
  Dbf1.FilterOptions := [foCaseInsensitive];
  Df1.Filter := 'AU=' + QuotedStr('anauthor');         // AU is the field name containing the authors
  
  Dbf1.Filtered := true;       // This selects the filtered set
  Dbf1.First;                  // moves the the first filtered data
  while not dbf1.EOF do        // prints the titles that match the author to the memo box
  begin
    memo1.Append(Dbf1.FieldByName('TI').AsString); // TI is the field name for titles
    dbf1.next;                                     // use .next here NOT .findnext!
  end;
  Dbf1.Close;

Notare che è possibile utilizzare Ddf1.findfirst per ottenere il primo record nell'elenco filtrato, quindi utilizzare Dbf1.next per muoversi tra i dati. Ho scoperto che l'utilizzo di Dbf1.Findnext causa un blocco del programma.

Questo database è stato generato utilizzando TurboBD che viene distribuito con Kylix 1. Non sono riuscito a far funzionare con Lazarus le table fatte con TurboBD; in ogni caso potete scaricare un tool da linea di comando dal sito di TurboDB che permette di convertire le table di TurboDB in altri formati.


Utilizzare TSdfDataset e TFixedDataset

TSdfDataset e TFixedDataset sono due semplici dataset che offrono un formato di memorizzazione testuale molto semplice. Questi dataset sono molto comodi per piccoli database, perché sono totalmente implementati come una unità object pascal, quindi non richiedono librerie esterne, e perché il loro formato testuale permette di modificarli facilmente con un editor di testo.

Per iniziare con questi formati, bisogna creare un file per il database iniziale. Il formato è davvero semplice, quindi si può utilizare un editor di testo per farlo.

Qui in basso è riportato un database di esempio per TSdfDataset. Notare che la prima linea ha i nomi dei campi e che si stanno utilizzando le virgole come separatori: 

ID,NAMEEN,NAMEPT,HEIGHT,WIDTH,PINS,DRAWINGCODE
1,resistor,resistor,1,1,1,LINE
2,capacitor,capacitor,1,1,1,LINE
3,transistor npn,transistor npn

E di seguito c'è un esempio di database da utilizzare con TFixedDataset. Ogni record occupa una quantità di spazio fissa e, se il campo è più piccolo, si dovranno usare degli spazi per riempirlo. 

Name = 15 chars; Surname = 15 chars; Tell = 10 chars; e_mail = 20 chars;
Piet           Pompies                  piet@pompies.net

Utilizzare i dataset direttamente

Alcune volte può risultare utile creare un dataset e lavorare su di esso completamente via codice; il codice seguente mostra esattamente come farlo. Notare alcune caratteristiche di TSdfDataset/TFixedDataset:

  • Le linee nel database possono avere una dimensione massima di circa 300. Si sta cercando un modo per ovviare al problema.
  • E' necessario aggiungere le definizioni dei campi. Alcuni dataset sono in grado di ricavare da soli questa informazione a partire dal file del database
  • Bisogna impostare FirstLineAsSchema a true, per indicare che la prima linea include il nome del campo e le posizioni
  • La proprietà Delimiter contiene il separatore per i campi. Non sarà possibile utilizzare questo carattere nelle stringhe nel database. In maniera simile, non sarà possibile avere dei caratteri di fine riga nel database perché essi segnano il passaggio da un record al successivo. E' possibile ovviare all'inconveniente sostituendo la virgola o il fine riga con un altro carattere poso usato, come ad esempio #. Quindi, mostrando i dati sullo schermo, tutti i caratteri # potranno essere convertiti in fine riga; al contrario, memorizzando i dati nel database, tutti i fine riga verranno convertiti in #. La funzione ReplaceString può tornare utile in questo caso.
constructor TComponentsDatabase.Create;
begin
  inherited Create;

  FDataset := TSdfDataset.Create(nil);
  FDataset.FileName := vConfigurations.ComponentsDBFile;

  // Not necessary with TSdfDataset
//  FDataset.TableName := STR_DB_COMPONENTS_TABLE;
//  FDataset.PrimaryKey := STR_DB_COMPONENTS_ID;

  // Adds field definitions
  FDataset.FieldDefs.Add('ID', ftString);
  FDataset.FieldDefs.Add('NAMEEN', ftString);
  FDataset.FieldDefs.Add('NAMEPT', ftString);
  FDataset.FieldDefs.Add('HEIGHT', ftString);
  FDataset.FieldDefs.Add('WIDTH', ftString);
  FDataset.FieldDefs.Add('PINS', ftString);
  FDataset.FieldDefs.Add('DRAWINGCODE', ftString);

  // Necessary for TSdfDataset
  FDataset.Delimiter := ',';
  FDataset.FirstLineAsSchema := True;

  FDataset.Active := True;

  // Sets the initial record
  CurrentRecNo := 1;
  FDataset.First;
end;

Quando si usa direttamente TSdfDataset, bisogna tenere presente che RecNo, benché sia implementato, non funziona come modo per muoversi attraverso il dataset sia in lettura che in scrittura dei record. Le funzioni standard di navigazione come First, Next, Prior e Last funzionano come previsto, quindi si dovranno usare quest'ultime piuttosto che RecNo. Se si è soliti utilizzare numeri di record assoluti per navigare in un database, è possibile implementare la propria versione di RecNo. E' sufficiente dichiarare una variabile globale di tipo longint chiamata CurrentRecNo che conterrà il valore corrente di RecNo. Bisogna ricordare che questa variabile seguirà la stessa convenzione di RecNo, quindi il primo record first sarà 1 (non è zero-based). Dopo l'attivazione del database bisogna inizializzarlo al primo record tramite TSdfDataset.First e impostare CurrentRecNo := 1 

{@@
  Moves to the desired record using TDataset.Next and TDataset.Prior
  This avoids using TDataset.RecNo which doesn't navigate reliably in any dataset.

  @param AID Indicates the record number. The first record has number 1
}
procedure TComponentsDatabase.GoToRec(AID: Integer);
begin
  // We are before the desired record, move forward
  if CurrentRecNo < AID then
  begin
    while (not FDataset.EOF) and (CurrentRecNo < AID) do
    begin
      FDataset.Next;
      FDataset.CursorPosChanged;
      Inc(CurrentRecNo);
    end;
  end
  // We are after the desired record, move back
  else if CurrentRecNo > AID  then
  begin
    while (CurrentRecNo >= 1) and (CurrentRecNo > AID) do
    begin
      FDataset.Prior;
      FDataset.CursorPosChanged;
      Dec(CurrentRecNo);
    end;
  end;
end;

Using with data-aware controls

Altri Links

Contributi e Modifiche

Questa pagina è stata convertita dalla versione di epikwiki.

Retrieved from "https://wiki.freepascal.org/index.php?title=Lazarus_Database_Tutorial/it&oldid=132510"