Multithreaded Application Tutorial/fr

From Lazarus wiki
Jump to navigationJump to search

Deutsch (de) English (en) español (es) français (fr) 日本語 (ja) polski (pl) português (pt) русский (ru) slovenčina (sk) 中文(中国大陆)‎ (zh_CN)

Vue d'ensemble

Cette page essayera d'expliquer comment écrire et corriger une application multi-tâches avec Free Pascal et Lazarus.

Une application multi-tâches est celle qui crée deux tâches d'execution ou plus en même temps.

Si vous êtes nouveau dans le multi-tâches, veuillez lire le paragraphe "Avez vous besoin du multi-tâches ?" pour découvrir si vous en avez vraiment besoin (Vous pouvez vous éviter beaucoup de maux de tête).

Une des tâches (threads) s'appelle la tâche principale . La tâche principale est celle qui est créé par le système d'exploitation lorsque notre application démarre. La tâche principale doit être la seule tâche qui met à jour les composants qui interfèrent avec l'utilisateur (autrement , l'application risque de planter ).

L'idée principale est que l'application peut faire quelques traitements en arrière-plan (dans une deuxième tâche) tandis que l'utilisateur peut continuer à travailler (en utilisant la tâche principale).

L'utilisation des tâches permet aussi d'avoir une application qui répond mieux. Si vous créez une application, et que, quand l'utilisateur appuie sur un bouton, l'application commence le traitement (un gros travail )... pendant le traitement , L'écran arrête de répondre, et donne à l'utilisateur la sensation que l'application est plantée, ce n'est pas très agréable. Si le gros travail fonctionne dans une deuxième tâche, l'application continue à répondre (presque ) comme si elle était en idle. Dans ce cas, il est préférable avant de commencer la tâche, de neutraliser les boutons de la fiche pour éviter que l'utilisateur ne démarre plus d'une tâche de travail .

Une autre utilisation , est de créer une application serveur qui est capable de répondre à beaucoup de clients en même temps .

Avez vous besoin du multi-tâche?

Si vous êtes un novice dans le multi-tâche et que vous souhaitez simplement rendre votre application plus nerveuse lorsqu'elle a une grande charge de travail, alors le multi-tâche n'est peut-être pas ce que vous recherchez. Les applications multi-tâches sont toujours plus difficile et à debogguer, elles sont souvent beaucoup plus complexes. Dans beaucoup de cas vous n'avez pas besoin du multi-tâche, une seule tâche est suffisante. Si vous pouvez fractionner les longues corvées de travail en plusieurs petits morceaux, utilisez plutôt Application.ProcessMessages, cette méthode laisse la LCL traiter tous les messages en attente et en retour. L'idée est de traiter une partie du travail, puis d'appeller Application.ProcessMessages pour voir si l'utilisateur abandonne ou clique quelque part, ou d'actualiser un indicateur de progression, et ensuite de continuer avec la partie suivante du travail, appeler Application.ProcessMessages et ainsi de suite. Pensez également, lors de l'exécution d'une application externe (à la manière d'un script) de laisser du temps à l'éventuel système tiers de digérer la commande en mettant votre application en pause à l'aide de la commande sleep(miliseconds) de l'unité sysutils.

Par exemple : Lecture d'un grand fichier et son traitement . Voir examples/multithreading/singlethreadingexample1.lpi.

Le multi-tâche est seulement nécessaire pour

  • le blocage des handles, comme les communications de réseau
  • l'utilisation de plusieurs processeurs à la fois
  • les algorithmes et les appels de bibliothèque, qui ne peuvent pas être fractionné dans de petites pièces.

La classe TThread

L'exemple suivant se trouve dans le répertoire examples/multithreading/.

Pour créer une application multi-tâches, la manière la plus simple est d'utiliser la classe TThread.

Cette classe permet la création d'une tâche supplémentaire (à côté de la tâche principale) de manière simple.

Normalement, il suffit de surcharger 2 méthodes: le constructeur Create, et la méthode Execute.

Dans le constructeur, vous préparez la tâche à s'exécuter, vous fixerez les valeurs initiales des variables ou des propriétés que vous souhaitez. Le constructeur original de TThread exige un paramètre appelé Suspended. Comme vous pourriez le prévoir, fixer Suspended = True empêchera la tâche de commencer automatiquement après sa création . Si Suspended = False, la tâche commencera à fonctionner juste après sa création, si Suspended = True elle ne fonctionnera qu'après l'appel de la méthode Start.

Light bulb  Remarque: La méthode Resume est obsolète depuis FPC 2.4.4. Elle est remplacée par Start.

A partir de FPC version 2.0.1 et au delà, TThread.Create a également un paramètre implicite de taille de la pile. Vous pouvez maintenant changer la taille de la pile par défaut pour chaque tâche que vous créez (si vous en avez besoin). Les appels de procedure récursifs dans une tâche sont un bon exemple. Si vous n'indiquez pas le paramètre de la taille de la pile, la taille de pile de l'OS par défaut est employée.

Dans la méthode surchargée Execute vous écrivez le code qui fonctionnera dans la tâche.

La classe TThread a une propriété importante : Terminated : boolean;

Si la tâche est une boucle (ce qui est habituel), la boucle devra être quittée quand Terminated passera à True (sa valeur est False par défaut). Ainsi dans chaque cycle, la tâche doit tester si Terminated vaut True, et si c'est le cas, doit sortir de la méthode Execute aussi rapidement que possible (après tout nettoyage nécessaire).

Gardez aussi à l'esprit que la méthode Terminate ne fait rien par défaut: la méthode Execute doit explicitement faire le nécessaire pour stopper son travail.

Comme nous l'avons expliqué plus tôt, la tâche ne devra pas interagir avec les composants visuels. Pour interagir avec l'utilisateur elle devra le faire dans la tâche principale. Pour faire cela, il faut utiliser la méthode Synchronize de la classe TThread. Synchronize prend en paramètre une méthode (qui, elle, ne prend aucun paramètre) comme argument. Quand vous appelez cette méthode au moyen de Synchronize(@MyMethod), l'execution de la tâche sera mis en pause, le code de MyMethod s'exécutera dans la tâche principale, et ensuite l'exécution de la tâche reprendra. Le fonctionnement exact de Synchronize dépend de la plate-forme, mais fondamentalement elle fait ceci: Elle se signale par un message sur la file d'attente de message principale et va dormir. Par la suite, lorsque la tâche principale traite ce message, elle appelle MyMethod. De cette façon MyMethod est appelé hors contexte, ce qui signifie pas pendant un évènement de déplacement de souris ou pendant un événement de peinture, mais après. Dès que la tâche principale a exécuté MyMethod, elle réveille la tâche en sommeil et exécute le message suivant. La tâche continue alors.

Il y a une autre propriété importante de la classe TThread: FreeOnTerminate. Si cette propriété est true, l'objet tâche est automatiquement libéré quand l'execution de la tâche (méthode .Execute) s'arrête, sinon l'application devra le libérer manuellement.

Exemple :

  Type
    TMyThread = class(TThread)
    private
      fStatusText : string;
      procedure ShowStatus;
    protected
      procedure Execute; override;
    public
      Constructor Create(CreateSuspended : boolean);
    end;
  constructor TMyThread.Create(CreateSuspended : boolean);
  begin
    FreeOnTerminate := True;
    inherited Create(CreateSuspended);
  end;
  procedure TMyThread.ShowStatus;
  // this method is executed by the mainthread and can therefore access all GUI elements.
  begin
    Form1.Caption := fStatusText;
  end;
  procedure TMyThread.Execute;
  var
    newStatus : string;
  begin
    fStatusText := 'TMyThread Starting...';
    Synchronize(@Showstatus);
    fStatusText := 'TMyThread Running...';
    while (not Terminated) and ([any condition required]) do
      begin
        ...
        [here goes the code of the main thread loop]
        ...
        if NewStatus <> fStatusText then
          begin
            fStatusText := newStatus;
            Synchronize(@Showstatus);
          end;
      end;
  end;

Voici l'application :

  var
    MyThread : TMyThread;
  begin
    MyThread := TMyThread.Create(True); // This way it doesn't start automatically
    ...
    [Here the code initialises anything required before the threads starts executing]
    ...
    MyThread.Start;
  end;

Si vous voulez rendre votre synchronisation plus flexible vous pouvez créer un événement pour cette tâche - de cette façon votre méthode synchronized ne sera pas étroitement couplée avec une fiche spécifique ou une classe - il suffit ensuite d'avoir une méthode répondant à l'évènement du thread. Voici un exemple :

  Type
    TShowStatusEvent = procedure(Status: String) of Object;

    TMyThread = class(TThread)
    private
      fStatusText : string;
      FOnShowStatus: TShowStatusEvent;
      procedure ShowStatus;
    protected
      procedure Execute; override;
    public
      Constructor Create(CreateSuspended : boolean);
      property OnShowStatus: TShowStatusEvent read FOnShowStatus write FOnShowStatus;
    end;
  constructor TMyThread.Create(CreateSuspended : boolean);
  begin
    FreeOnTerminate := True;
    inherited Create(CreateSuspended);
  end;
  procedure TMyThread.ShowStatus;
  // this method is executed by the mainthread and can therefore access all GUI elements.
  begin
    if Assigned(FOnShowStatus) then
    begin
      FOnShowStatus(fStatusText);
    end;
  end;
  procedure TMyThread.Execute;
  var
    newStatus : string;
  begin
    fStatusText := 'TMyThread Starting...';
    Synchronize(@Showstatus);
    fStatusText := 'TMyThread Running...';
    while (not Terminated) and ([any condition required]) do
      begin
        ...
        [here goes the code of the main thread loop]
        ...
        if NewStatus <> fStatusText then
          begin
            fStatusText := newStatus;
            Synchronize(@Showstatus);
          end;
      end;
  end;

Voici l'application :

  Type
    TForm1 = class(TForm)
      Button1: TButton;
      Label1: TLabel;
      procedure FormCreate(Sender: TObject);
      procedure FormDestroy(Sender: TObject);
    private
      { private declarations }
      MyThread: TMyThread; 
      procedure ShowStatus(Status: string);
    public
      { public declarations }
    end;
  procedure TForm1.FormCreate(Sender: TObject);
  begin
    inherited;
    MyThread := TMyThread.Create(true);
    MyThread.OnShowStatus := @ShowStatus;
  end;
  procedure TForm1.FormDestroy(Sender: TObject);
  begin
    MyThread.Terminate;
    MyThread.Free;
    inherited;
  end;
  procedure TForm1.Button1Click(Sender: TObject);
  begin
   MyThread.Start;
  end;
  procedure TForm1.ShowStatus(Status: string);
  begin
    Label1.Caption := Status;
  end;

Choses spéciales dont il faut s'occuper

Il y a une prise de tête potentielle dans Windows avec les Threads si vous employez l'option -Ct (contrôle de pile ). Pour des raisons obscures le contrôle de pile se "déclenchera" sur un quelconque TThread.Create si vous employez la taille de pile par défaut. Le seul contournement(à ce problème) pour le moment est simplement de ne pas utiliser l'option -Ct. Noter qu'il ne cause pas d'exception dans la tâche principale, mais dans celle nouvellement crée. Ainsi, tout se passe comme si la tâche n'avait jamais commencée.

Voici un code correct permettant de vérifier les exceptions qui peuvent se produire dans la création d'une tâche:

     MyThread:=TThread.Create(False);
     if Assigned(MyThread.FatalException) then
       raise MyThread.FatalException;

Ce code assure que toute exception qui se produit pendant la création d'une tâche soit relevée (et traitée) dans votre tâche principale.

Les unités nécessaires pour une application multi-tâches

Vous n'avez besoin d'aucune unité spéciale pour ceci pour travailler avec Windows . Cependant avec Linux, MacOSX et FreeBSD, vous avez besoin de l'unité cthreads et elle doit être la première untité utilisée du projet (l'unité du programme , .lpr)!

Ainsi, votre code d'application Lazarus devrait resssembler à :

  program MyMultiThreadedProgram;
  {$mode objfpc}{$H+}
  uses
  {$ifdef unix}
    cthreads,
  {$endif}
    Interfaces, // this includes the LCL widgetset
    Forms
    { add your units here },

Si vous oubliez ceci vous obtiendrez cette erreur au démarrage :

 Le fichier binaire n'a aucun support de tâches compilé en lui.
 Recompiler l'application avec un gestionnaire de thread dans la clause uses du programme avant d'autres unités utilisant
 les tâches. (Pour le message en anglais voir version anglaise de cette page)

Support SMP

La bonne nouvelle est que votre application travaille en multi-tâches correctement de cette façon, elle est déjà prête pour le SMP!

Deboguer les application multi-tâches avec Lazarus

Le deboguage sur Lazarus n'est pas encore entièrement fonctionnel.

Deboguer la sortie

Dans une application a une seule tâche, vous pouvez simplement écrire sur la console/le terminal/n'importe quoi et l'ordre des lignes est le même avec lesquelles elles ont été écrites . Dans une application multi-tâche les choses sont plus compliquées. Si deux tâches écrivent, c'est à dire qu'une ligne est écrite par la tâche A avant une ligne par la tâche B, alors les lignes ne sont pas neccessairement écrites dans cet ordre. Il peut même se produire qu'une tâche écrive sa propre sortie pendant qu'une autre tâche soit déjà en train d'écrire sur la sortie, résultant en des lignes qui se mélangent.

L'unité LCLProc contient plusieurs fonctions , pour laisser chaque tâche écrire à son propre fichier journal:

  procedure DbgOutThreadLog(const Msg: string); overload;
  procedure DebuglnThreadLog(const Msg: string); overload;
  procedure DebuglnThreadLog(Args: array of const); overload;
  procedure DebuglnThreadLog; overload;

Par exemple : Au lieu de writeln('Some text ',123); utilisez

 
  DebuglnThreadLog(['Some text ',123]);

Ceci ajoutera une ligne 'Some text 123' à Log<PID>.txt, où <PID> est l'ID du processus de la tâche courante.

C'est une bonne idée d'enlever le fichier journal avant chaque exécution :

 rm -f Log* && ./project1

Linux

Si vous essayez de deboguer une application multi-tâches sous Linux, vous aurez un grand problème : le serveur X va crasher !

On ne sait pas comment résoudre cela proprement, mais un contournement de ce problème est:

Créer une nouvelle instance de X avec :

 X :1 &

Il s'ouvrira, et quand vous commuterez vers un autre bureau (celui avec lequel vous travaillez en appuyant sur CTRL+ALT+F7), vous pourrez retourner vers le nouveau bureau graphique avec CTRL+ALT+F8 (si cette combinaison ne fonctionne pas , essayez avec CTRL+ALT+F2... celui-ci a fonctionné avec Slackware).

Alors vous pourriez , si vous voulez , créer une session bureau au démarrage de X avec:

 gnome-session --display=:1 &

Puis, dans Lazarus, avec la boite de dialogue "paramètres d'exécution..." du menu Exécuter, cocher "Utiliser l'affichage" et entrez :1.

Maintenant l'application s'exécutera sur le deuxième serveur X et vous serez capable de la déboguer avec le premier.

Ceci a été testé avec Free Pascal 2.0 et Lazarus 0.9.10 sur Windows et Linux.



Au lieu de créer une nouvelle session X, on peut employer Xnest. Xnest est une session X session sur une fenêtre . En l'utilisant, le serveur X n'est pas bloqué pendant le debogage des processus, et c'est beaucoup plus facile de deboguer sans être tenu de changer de terminals.

La ligne de commande pour exécuter Xnest est

 Xnest :1 -ac

pour créer une session X sur :1, et interdire de contrôle d'accès.

Widgetsets

Les interfaces win32, gtk et carbon supportent entièrement le multi-tâches. Ceci signifie que, TThread, les sections critiques et Synchronize fonctionnent.

Les sections critiques

Une section critique est un objet employé pour s'assurer, qu'une certaine partie du code est exécutée seulement par une tâche à la fois. Une section critique doit être créée /initialisée avant qu'elle puisse être employée et être libérée quand elle n'est plus nécessaire.

Les sections critiques sont normalement employées de cette façon :

Ajouter l'unité SyncObjs.

Déclarer la section (de manière globale pour toutes les tâches qui devraient accéder à la section):

  MyCriticalSection: TRTLCriticalSection;

Créer la section :

  InitializeCriticalSection(MyCriticalSection);

Executer quelques tâches. En faisant quelque chose exclusivement

  EnterCriticalSection(MyCriticalSection);
  try
    // accéder à quelques variables , écrire les fichiers , envoyer quelques paquets de réseau , etc
  finally
    LeaveCriticalSection(MyCriticalSection);
  end;

Après que toutes les tâches soient terminées , libérer la section critique :

  DeleteCriticalSection(MyCriticalSection);

Comme alternative, vous pouvez employer un objet TCriticalSection. La création fait l'initialisation, la méthode Enter fait pénétrer dans EnterCriticalSection, la méthode Leave fait LeaveCriticalSection et la destruction de l'object fait la suppression.

Par exemple : 5 tâches incrémentant un compteur. Voir lazarus/examples/multithreading/criticalsectionexample1.lpi

PRENDRE GARDE : Il y a deux jeux pour les 4 fonctions ci-dessus. Celui de la bibliothèque RTL et celui de la LCL. Celui de la LCL est défini dans les unités LCLIntf et LCLType. Tous les deux fonctionnent plus ou moins de la même façon . Vous pouvez les employer tous les deux en même temps dans votre application , mais vous ne devriez pas employer une fonction de la bibliothèque RTL avec une section critique LCL et vice-versa.


Partage de variables

Si certaines tâches partagent une variable, seulement en lecture, alors il n'y a pas à s'inquiéter. juste la lire. Mais si une ou plusieurs tâches modifient la variable, alors vous devez vous assurer , que seulement une tâche accède aux variables à la fois .

Par exemple : 5 tâches incrémentant un compteur. Voir lazarus/examples/multithreading/criticalsectionexample1.lpi

Attente une autre tâche

Si une tâche A a besoin du résultat d'une autre tâche B, elle doit attendre , jusqu'à ce que B ait fini .

Important: La tâche principale ne devrait jamais attendre pour une autre tâche. Au lieu de cela utilisez Synchronize (voir ci-dessus).

Pour un exemple voir: lazarus/examples/multithreading/waitforexample1.lpi

{ TThreadA }

procedure TThreadA.Execute;
begin
  Form1.ThreadB:=TThreadB.Create(false);
  // create event
  WaitForB:=RTLEventCreate;
  while not Application.Terminated do begin
    // wait infinitely (until B wakes A)
    RtlEventWaitFor(WaitForB);
    writeln('A: ThreadB.Counter='+IntToStr(Form1.ThreadB.Counter));
  end;
end;

{ TThreadB }

procedure TThreadB.Execute;
var
  i: Integer;
begin
  Counter:=0;
  while not Application.Terminated do begin
    // B: Working ...
    Sleep(1500);
    inc(Counter);
    // wake A
    RtlEventSetEvent(Form1.ThreadA.WaitForB);
  end;
end;

Fork

Prenez garde au fait que lorsque vous forkez une application multi-threads, tous les threads créés et s'exécutant avant l'appel à fork (ou fpFork) ne seront pas exécutés dans le processus enfant. Comme indiqué dans la 'man page' de la fonction fork(), tous les threads qui sont en cours d'exécution avant l'appel à fork seront dans un état indéterminé.

Donc attention a toutes les thread s'initialisant avant l'appel d'un fork (même dans la section initialization ). Ils ne fonctionneront pas.

procédures/boucles parallèles

Un cas particulier de multi threading est exécute une procédure unique en parallèle. Voir procédures Parallèles.

Traitement distribué / Distributed computing

Le prochain grand pas après le 'multi-threading' est d'exécuter des threads sur plusieurs machines.

  • Vous pouvez utiliser une des suites TCP comme synapse, lnet ou indy pour la communication. Cela vous donnera le maximum de flexibilité et est surtout utilisé dans les applications client / serveur.
  • Vous pouvez utiliser une bibliothèque de passage de message comme MPICH, utilisé sur le clusters pour 'HPC' (High Performance Computing).